*temp DPRthoughts 0
*temp shenanigans true
*temp earlyout false
*temp injured false
*temp fulldpr false
*temp archquestions 0
*temp stroll false
*temp trust false
*temp workedout false
*temp money false
*temp incharge false
*temp brushoff false
*temp brutality false
*temp wilqueer false

*if brutal > 0
    *set brutality true
    
*if motive = 3
    *set money true
*if mc_health > 1
    *set injured true

*if instinctive > 65
    You're well acquainted with the experience of spending hours upon hours doing absolutely nothing, and you've forced yourself to learn to tolerate it. A little boredom pales in comparison to what you've been through in the Coven.
    
*elseif instinctive < 35
    You're well acquainted with the experience of spending hours upon hours doing absolutely nothing. It's fortunate that you're naturally patient, though even were you not, a little boredom pales in comparison to what you've been through in the Coven.
    
*else
    You're well acquainted with the experience of spending hours upon hours doing absolutely nothing. You don't have strong feelings on it; a little boredom pales in comparison to what you've been through in the Coven.
    
Speaking of, you should hear from Control Group once morning breaks. She'll want a report for the others, and after several days of holding pattern waiting for Architect and Wyrd to launch an appropriately crashable gig, there's finally something concrete for you to give her.

The thought sends a shiver of apprehension down your spine. One step. One step down the road of earning real trust from the Coven.

But first…
*page_break More waiting.

The next hours blur together. Wait around long enough, and you learn how to deactivate your brain, unfocusing your mind like you might your eyes. Better that than hours caught up in your thoughts.

At length, a dull buzz snaps you out of your trancelike state. The noise hums unpleasantly through your teeth as you reattenuate to the waking world. You begin casting about nearby until you find your earpiece on the mattress, right where you left it last night. With a grimace, you slip it back into your ear, pinching its bud in order to open communications.

"Receiving."

[i]"So, how'd it go?"[/i] Control Group's voice, as always is chipper and warm.

*if expressive < 35
    "Successfully."

    You hear a snort of a laugh. [i]"I see you're talkative as ever, Dime."[/i]
    
    "Yeah."

*else
    "Architect and Wyrd want to meet up with me."
    
    [i]"That's a success. Good going, Dime."[/i]
    
    "Thanks."
    
Dime, short for Paradigm. Your name to Control Group and the entire Coven. The only name you've been called these past five years.

'Subject' doesn't really count.

Almost everyone you've known in that period has a similar designation. For instance Control Group herself, your handler and trainer.
*set dime true

Whenever @{fighting_style you drop your guard and get punished with a shot to the face|you lose your head in the heat of the moment instead of thinking on your feet|you fail to make effective use of your tendrils or protective coating|DUMMY}, it's Control Group's voice you hear in your head to admonish you and urge you to do better.
*fake_choice
    #She has my best interests at heart.
        *set loyal +1
        *set rel_cg +2
        Sometimes she's a hardass. On the other hand, if she'd gone easier on you, then you doubt you'd have the skills to survive out here. You imagine yesterday without all of CG's training and wince.
        
    #She's pretty much the closest thing I have to a friend these days.
        *set break +1
        *set rel_cg +4
        You don't know whether that says more about her personality or your lack of options.
        
    #Honestly, she can go right to hell.
        *set cg_dislike true
        *set seethe +1
        *set rel_cg -7
        And she can take her 'training' and 'supervision' with her.
        
Normally, you call Control Group…
*fake_choice
    #CG.
        *set cg "CG"
        *set cgdisplay 2
    #Cee.
        *set cg "Cee"
        *set cgdisplay 3
    #...Control Group. Well. Control.
        *set cg "Control"

*if rel_cg > 40
    [i]"Oh, Dime. Tell me you didn't get too beat up?"[/i] $!{cg} continues.

*else
    [i]"You didn't get too hurt, right?"[/i] $!{cg} continues. Her tone has grown a little detached. You suspect she's asking because she needs to rather than any real concern.

*choice
    *selectable_if (mc_health = 1) #I tell her I'm fine.
        *set rel_cg +1
        "I'm good. @{nodecrushed Lost a node, but i|I}t was nothing I couldn't handle."
        
        *if rel_cg > 40
            @{nodecrushed [i]"Poor little guy. Glad to hear you managed okay otherwise."[/i]|[i]"Happy to hear it."[/i]}
            
            "Thank you."
            
        *else
            @{nodecrushed [i]"A node's an acceptable loss. You're intact. That's what matters."[/i]|[i]"Good. I suppose some of your lessons had to sink in sooner or later, Dime."[/i]}
            
            You're glad that there's no need to hide your scowl.
        
        *label drinkyjuice
        [i]"Regardless,"[/i] $!{cg} continues. [i]"Make sure you're topped off on Juice before you meet them. Precautions are essential."[/i]
        *goto juice
    *selectable_if (mc_health = 1) #I joke around that I'm injured.
        *if expressive < 36
            *set expressive %+ 5
            *set rel_cg +4
            "I pulled a muscle."
            
            …You're maybe not very good at joking around.
            
            [i]"A muscle? Dime, you can't be—"[/i] $!{cg} she pauses. [i]"Wait, was that a joke? That's not like you. Well, actually the 'joke' itself was very like you. Just not that you attempted it in the first place."[/i] There's a long pause. You're unsure how to respond. Eventually, $!{cg} breaks her own silence. [i]"In any case, it's worth topping off on Juice even if you're not injured, just as a precaution."[/i]
            *goto juice
        *else
            "Oof, I dunno, $!{cg}, I think I've got kind of a cramp in my calf."
            
            *if rel_cg > 40
                *set rel_cg +2
                She laughs.
                
                [i]"Hate to ask you to press on with such a grievous injury, Dime, but I'm going to need you to fight through the pain."[/i]
                
                You give a put-upon sigh. "I suppose I can try."
                
                *goto drinkyjuice
            *else
                *set rel_cg +3
                She laughs, the startled outburst of someone who wasn't expecting a joke. [i]"Not like you to loosen up around me, Dime."[/i]
                *fake_choice
                    #"Don't expect it to become a habit."
                        $!{cg} snorts. [i]"Fine, fine, I'll take what I got."[/i]
                        
                    #"Whatever." Part of me already regrets joking around.
                        Are you really so starved for conversation that you'll stoop to bantering with Control Group, as if she could ever be a friend of yours?
                        
                        It was a moment of weakness.
                        
                        $!{cg} falls quiet. The moment is dead.
                        
                    #"Maybe I want to turn a corner."
                        You don't like $!{cg} and you know it's mostly mutual. However, you don't have any choice but to work with her. Given the circumstances, your life would be much easier if you could both at least be cordial with each other.
                        
                        [i]"Fair enough."[/i]
                        
                    #"Maybe I want to turn a corner." I'm lying.
                        *set seethe +1
                        *set rel_cg -1
                        You don't like $!{cg}. That doesn't mean you can't pretend, if it's to your advantage.
                        
                        [i]"Hm."[/i] She sounds more dubious than you would have liked.
            
                "Anything else for me?" you prompt her.
                
                [i]"No, not for now. Just make sure you're topped off on Juice before you meet them. Precautions are essential."[/i]
                *goto juice
    *selectable_if (mc_health =1) #I lie and claim to be injured.
        *set break +1
        "Actually $!{cg}, I'm kind of banged up here." You feign strain, a little raspiness. Feigning fatigue isn't necessary.
            
        There's a pause, and then $!{cg} answers, incredulous. [i]"Paradigm, are you angling for sympathy or something? I don't have time for screwing around."[/i]
            
        "I'm not," you protest, but it's too little too late.
            
        [i]"Cut the bullshit, Dime."[/i]
            
        You subside. There's no arguing with that tone. You may have forgotten just how good $!{cg} is at reading you.
            
        $!{cg} sighs heavily. [i]"As soon as you feel like taking this seriously, how about you make sure you're topped off on Juice, and then get ready for that meeting?"[/i]
        *goto juice
    *selectable_if (rel_cg < 40) #"What do you care?"
        *set seethe +1
        *set rel_cg -2
        $!{cg} sighs tersely. [i]"Because, Dime, if you're injured, then your mission might be compromised."[/i]
        
        "I can handle myself."
        
        [i]"Dime, just because you're out in the field doesn't—"[/i] $!{cg} stops. There's a pointed silence. You imagine she's composing herself; it's a good few seconds until she resumes. [i]"If you want to be trusted with future assignments, then you play ball, understand?"[/i]
        
        Any modest satisfaction you may have derived from thumbing your nose at her is instantly wiped away. "Right," you mutter.
        
        [i]"Make sure you're Juiced up and go meet them, Paradigm."[/i]
        *goto juice
    *selectable_if (mc_health > 1) #I admit that I'm hurt.
        "Now that you mention it…"
        
        [i]"You're injured."[/i]
        
        "Yeah."
        
        $!{cg} sighs. [i]"Badly?"[/i]
        
        *if mc_health =2
            "It could be worse."
            
            [i]"That's something, I suppose."[/i]
        *else
            "I'm still moving at least."
            
            There's a faint hiss. Air through clenched teeth. [i]"Fabulous. Just fantastic."[/i]
        *fake_choice
            #"Sorry."
                *set rel_cg +1
                [i]"You don't need to apologise, Dime. Just do better next time."[/i]
            #"I'll be fine."
                [i]"Hmph. Here's hoping. Do better next time, okay?"[/i]
                
        *if rel_cg < 40
                "Sure." You force out.
                
        *else
                "I will."
                
        Another sigh. [i]"Thanks for telling me, Dime. Don't push yourself too hard and let the Juice take care of it. Shouldn't take more than a day or two."[/i]
            
        *set rel_cg +3
        *goto juice
    *selectable_if (mc_health > 1) #I lie and claim that I'm fine.
        *set break +1
        *set rel_cg -1
        "I'm fine. Nothing to worry about."
        
        Though you try to sound casual, $!{cg} has spent a lot of time with you and has a hell of a nose for bullshit.
            
        [i]"Paradigm."[/i] Her voice is sharp. [i]"Don't lie to me, please."[/i]
        
        You say nothing. There's no arguing with that tone of voice.
        
        [i]"If you're injured, let the Juice take care of it and don't push yourself. You'll be fine in a day or two."[/i]
        *goto juice
            

*label juice
Ah, Juice.

"Sure $!{cg}. I'll go dose now. Speak to you tomorrow."

[i]"Okay. Same time tomorrow then. Don't be late."[/i] There's no noise to signify the closing of the channel. You wonder occasionally if that's deliberate, to stoke your paranoia. Somebody could always be listening in.

Anyway…
*page_break There's Juice to drink.

Given the Juice's importance, you don't store it just anywhere. You aren't allowed to store it just anywhere. After flicking your lamp on and dousing yourself in sickly yellow light, you move to the back of the container and crouch down to the ground. Briefly extending a razor-thin claw of your membrane, you dig it into the floor, prising up a false panel and revealing a shallow recess containing a small rectangular box. Extricating the box, you flip it over and are faced with a nine-digit combination pad—blank keys of course, that's standard security—of which you carefully press six buttons. No room for slip ups; a wrong combination destroys the contents.

*if knowledge < 20
    [i]The keypad buzzes as you finish inputting a string of 9s.[/i]
    
    [i]"$!{mc_name}… Why am I not surprised?"[/i]
    
    You force away the memory, tasting bile.

With a hiss of pressurised air, the box opens. Nestled within is a vial filled with a luminescent purple liquid.

Your fingers twitch. Your throat is dry.

One dose. You're not permitted any more than that.
*choice
    #Drink your Juice.
        *goto slurp
        
*label slurp
*set juice 100
*if mc_health > 2
    *set mc_health -1
    *set recovery 2

*elseif mc_health = 2
    *set mc_health 1
 
*set nodedesc 1
*set mutationdesc 1
*set injurydesc 1
You put the vial to your lips and tip it backward. A metallic tang hits your tongue and a wave of invigorating energy floods your system, sending your back arching and your body shuddering. You can feel it all. Everything. Every inch of every part of you is alight with electricity. 

Thirty seconds. One minute. Two minutes. You stare unseeing, grappling with the overwhelming sensations of the Juice coursing through you. Almost three full minutes pass before you finally come crashing back to cognisance.

As you return to yourself, you feel your tendrils twitching and twisting from your shoulders, fully extended. @{speciality Something wriggles in your gut, all too familiar instincts crowding at the edge of your mind to [i]hunt. eat.[/i] You swallow back the urge to vomit. The last thing you need is a node scuttling around.|Your body ripples, skin beginning to pinch and distort. Beneath the surface, muscle and bone creak, tensing for change. Clenching your jaw, you will the tremors to halt, holding tight to your natural form. The last thing you need is to go for a stroll through the streets with an extra arm.|The skin of your face crawls, the membrane extended across your cheeks and steadily beginning to thicken. Clenching your jaw, you concentrate on pulling the forming carapace back. The last thing you need is to go for a stroll through the streets with armour all over your face.|DUMMY}
*choice
    #I hate this so damn much.
        *set hate +1
        Putting this poison in your body, having no choice in the matter… it's yet another heaped shovel on the pile of bullshit that is your life.
        
    #It is what it is.
        *set content +1
        This is just something you have to do. Your feelings are irrelevant.
        
    #I'd endure worse for powers.
        *set trade +1
        Sure, this isn't a pleasant experience, but last night's dream is a perfect reminder of the snowball's chance in hell normals have against parahumans.
        
You never ignited. You weren't born with powers. You're certainly not a cybernetically-enhanced augment. You owe your abilities wholly to the Juice, and without it—

Diverting that train of thought takes some effort. Your dependence is an unpleasant reality at the best of times, and you're a long way from your best. Even the adjusted best of the present day.

Instead, you concentrate on the physical. It feels as if you've successfully pushed your membrane and tendrils back beneath the surface, but it does you no harm to double check. A couple of days ago you managed to scavenge half a broken mirror, which now stands awkwardly propped against the side of the container. Squatting down to its level to study your reflection in its scratched surface, you don't bother trying to hold back a grimace. @{mc_exbuild |Though you never had much body mass to spare, now you're verging on emaciated.|What little lean muscle you had is long gone; you're so gaunt it's painful.|There's nothing middling about your build any more; you're gaunt, bordering emaciated.|The difference in your physique is night and day, from heavy and well built to painfully, unhealthily thin.|There's barely a trace of your former musculature; your frame is painfully gaunt.}

Otherwise, there's no sign of any @{speciality nodes wriggling beneath the surface|appendages sticking out of the wrong place|half-formed armour plates|DUMMY}. You're halfway to being presentable. However, even without a membrane covering your face or tendrils sprouting from your shoulders, the Juice has still left an indelible mark upon you.

Specifically it's…
*choice
    #My hair, bleached white as bone.
        *set feature 1
        *set feathair true
        *set mc_hair 10
        Your every lock of hair is an unnaturally stark white.
        
        You don't know exactly when it changed. The memories are hazy. One day, you caught a glimpse of yourself in passing and had to look twice.
    #My eyes, pallid and ghostly.
        *set feature 2
        *set feateyes true
        *set mc_eyes 7
        Both of your eyes are drained of all colour. You imagine that they must be unsettling. 
        
        You can't imagine that anyone's discomfort is stronger than the disquiet of seeing a stranger's eyes looking back from the mirror.
    #My shoulders, crossed by a network of black veins.
        *set feature 3
        *set featdetail 2
        The intricate lattice crosses roughly where your two tendrils of choice usually emerge.
        
        Provided you pay attention to your clothing and in particular ensure you never go sleeveless, you can conceal the veins.
       
    #My abdomen, etched with mawlike markings.
        *set feature 4
        *set featdetail 3
        Perhaps markings isn't the correct word. The flesh of your stomach is ridged, almost scarified in places. At the right angle, it resembles a sunken mouth.
        
        *if speciality = 2
            An ever-present reminder of what your powers can do. The maw isn't even in the same position as yesterday's mutation.
            
        *else
            Though the maw doesn't interact directly with your powers, there's an undeniable shiver each time you extend your membrane that far down your body.
            
        Sometimes, you could swear that you feel the mouth shifting and writhing of its own accord.
        
*set mc_build 7
*set specialdesc 1
*set appearancestatus 2
@{feature Brushing a hand across your hair, you swallow and turn away.|Maintaining your own gaze is difficult. You manage a few more seconds before turning away.|Concealment makes you no less conscious of their presence. Nevertheless, you can only bear to look at the markings for so long.  Reaching up, you tug the ragged neck of your t-shirt, adjusting it until the veins are fully out of sight.|You can take the scantest consolation in not having to see your own stomach the majority of the time; the maw is a concealable mark. That said, an abdominal mouth would be very difficult to explain away if anyone happened to catch a glimpse of it.}

@{feature |||A mirthless smile crosses your face in the mirror. Right. Like you're going to take your shirt off in front of anyone.}

*page_break
You've more than had your fill of the mirror and rise back to your feet. For a few seconds you stare up at the container's ceiling, sorting through your jumbled thoughts. You nudge aside your preoccupation with your appearance and the Juice's effects on it, pull away from dwelling on the nightmares, and disentangle yourself from fixating on your obligations to $!{cg} and the Coven. Eventually, you manage to pull your focus towards the upcoming rendezvous.

Even on foot it won't take long to reach the address Architect gave you. By your reckoning, you still have another hour before you need to start getting ready. With so much buzzing around your head and filled to the brim with Juiced up energy, you doubt you'll be able to mentally disengage again, so perhaps you can spend the remaining time productively.

One of the benefits of the current state of affairs is the novelty of time that is actually your own. More or less.
*choice
    #I'll run through a workout routine. [Guts boost]
        *set workedout true
        *if guts < 20
            You're in a pretty sorry physical state@{speciality , even in spite of your combat training.|.|.|DUMMY} Your powers can only compensate for so much. Yesterday, your lack of conditioning didn't bite you too hard, and you recognise that good fortune for what it is. Luck won't last forever.
            
        *else
            You're nothing close to your physical peak, and with plenty of exertions and altercations undoubtedly in your near future, you need to put in some serious effort if you plan to meet those challenges.
            
        *if mc_health > 1
            Working out while injured demands an extra level of concentration, and you take care to keep the strain on your wounds to a minimum as you first stretch and then move on to callisthenics. It's not easy, and you're pouring with sweat within a few minutes. Nevertheless, you persist.
            *goto exercisemenu
            
        For the better part of the next hour, you steadily move through a series of stretches and callisthenic exercises, slowly increasing the intensity over time. You're soon breathing hard, and you work up a real sweat by the time you're finished.
        
        *label exercisemenu
        *set guts +5
        *choice
            #Will it ever be enough?
                *set seethe +1
                Enough strength to break your shackles. Enough stamina to outrun your leash.
                
                Doubtful.
                *goto getready
            #The better my conditioning, the better it is for the mission.
                *set loyal +1
                You feel good for putting in the work. More prepared. More effective.
                *goto getready
            #It's strange to be able to set my own schedule.
                *set break+1
                *goto autonomy
    #I'm still trying to catch up on everything I've missed. [Knowledge boost]
        There's a five year gap in your knowledge both domestic and international, parahuman and ordinary. Although $!{cg} briefed you on some of the basics before you were despatched on the assignment, you'd like to reduce the risk of blowing your cover. In the most immediate sense, you're a newcomer to Alderbrook and can only benefit from knowing the town better. 
        
        Your crummy phone sure doesn't have internet, and running a computer here would be pretty much impossible, so research looks like scanning through a couple of discarded newspapers and magazines as well as last year's tourists' guide to Alderbrook. The lattermost is something you're surprised both that it exists—Alderbrook isn't exactly a primo vacation destination—and that $!{cg} actually grabbed a copy for you.
        
        Spending an hour reading makes you feel like you're laying the first foundations of bridging that half decade chasm.
        *set knowledge +5
        *choice
            #There's no reclaiming the time.
                *set seethe +1
                Even if you make up every inch of ground on your knowledge, you'll never get those five years back.
                
                Five years and counting.
                *goto getready
            #Hopefully this helps the mission.
                *set loyal +1
                *label hopefully
                The more prepared you are, the more effective you'll be.
                *goto getready
            #I almost can't believe I get to do this.
                *set break +1
                *label autonomy
                You keep waiting for the other shoe to drop. Having so much autonomy is utterly alien.
                *goto getready
    #I'll patrol outside and ensure nothing is out of place. [Observation boost] 
        *set earlyout true
        It's more important than ever to maintain a good awareness of your surroundings, especially with an assignment that calls for attention to detail. Besides, maybe the fresh air will do you some good.
        
        *label routine
        @{earlyout You move through an accelerated version of your morning routine,|You begin moving through your morning routine,} peeling off yesterday's @{injured messed up |} clothes and reluctantly walking into the corner of your container that $!{cg} dubiously dubbed the shower when she first showed you the place. Said 'shower' consists of two metal bars welded to the floor at right angles to create a sad excuse for a basin, along with a drain fitted to allow water to flow out onto the ground outside.
        
        Speaking of water, all you've got is a bucket filled up from the nearby mains, which is miraculously intact given the building's dilapidated state. $!{cg} told you that she'd made sure there was running water available but you're not certain you believe her. Regardless the water is, naturally, ice cold.
        
        At least it's clean?
        
        One skin-numbingly freezing bucketful of liquid despair later, you've cleansed your body of the worst of the grime and are towelling off. There's nothing much you can do for your hair with the limited facilities, so you're forced to leave it be. @{natural Honestly, you've lacked access to proper haircare for a long while and you know it's in a horrible state, damaged to an extent you're not even sure can be repaired. | }@{mc_hairlength ||It's just as well you keep it so short.|It's just as well you keep it so short.||||} Once you're sufficiently dry, you start to get dressed. The Coven didn't provide you with much in the way of clothing and you have no means of expanding your wardrobe, so presently you're limited to a handful of threadbare t-shirts and a couple pairs of jeans that are more rip than denim. Add your singular jacket, battered and heavily patched, and you're looking—okay you can't kid yourself by claiming you look good, so you settle on 'semi-acceptable for polite society'.
        
        *if earlyout
            *goto observe
        *else
            *goto pastasighted
    #I stole a padlock the other day. I'll practice with that. [Subterfuge boost]
        *if subterfuge < 20
            Upon your arrival in the industrial yard you took an embarrassing defeat at the hands of a locked gate that proved impervious to your every attempt to open it. Ultimately you were forced to deploy your powers to break off the padlock and gain entry (at which point you realised you were standing roughly five feet from a gaping hole in the fence. Not your finest hour). While you'll always have the option of brute force, the ordeal made it abundantly clear that you need a lot more experience if you hope to quietly infiltrate anywhere.
            
        *elseif subterfuge > 50
            Gratifyingly, the locked gate of the industrial yard proved no match to your lockpicking skills earlier in the week. Even if you're rusty and don't have the benefit of all your old tools, you've still got it. That said, you could always stand to sharpen up, especially if you hope to recapture your former expertise. It's why you even took a run at the gate instead of just slipping through a gap in the fence. Practice, and practice again.
            
        *else
            Though you're not too bad at picking locks, the industrial yard's gate proved a daunting task earlier in the week to the point that you almost gave up and slipped through one of the holes in the fence with your tail between your legs. If a random padlock in a junk heap like this is almost too much to overcome, then you certainly need more experience if you hope to quietly infiltrate anywhere.
            
        You have no doubt that there's more breaking and entering in your future, and you'd like other options than kicking down the front door. You spend a productive half hour picking and unpicking the padlock, and then move on to some light stretches and balancing exercises that should help you disperse your weight for quieter footsteps.
        *set subterfuge +5
        *choice
            #If only I could sneak away from all of this.
                *set seethe +1
                Yeah. If only.
                
                You're under no illusions.
                *goto getready
            #Hopefully this helps the mission.
                *set loyal +1
                *goto hopefully
            #I almost can't believe I get to choose how to spend my time.
                *set break +1
                *goto autonomy
            

*label observe
*page_break
Reasoning that you're unlikely to return once you finish your patrol, you gather the essentials—phone, earpiece, keyring, worn out old satchel—before cracking open the container doors and stepping outside. Locking everything up with practiced ease, you set to strolling around the yard and its immediate surroundings.

There isn't much to see. This is, after all, still Wesson Parks. Even so, you make a small game of it as you walk. Every small bit of movement is vigilantly inspected, every piece of trash you come across analysed for 'clues'. 

It's not the worst way to kill an hour, and as you complete your final circuit of the building, you're feeling more confident in your ability to spot the fine details.
*set observation +5
*choice
    #It says something that walking around is a novelty.
        *set seethe +1
        A bitter realisation that dents your good mood.
    #This can only help the mission.
        *set loyal +1
        A keen eye will come in handy, you're sure.
    #I almost can't believe I can just choose to do this.
        *set break +1
        Having so much autonomy is utterly alien. You keep waiting for the other shoe to drop.
        
The last part of your route takes you back past the shipping container. As you approach, however, something catches your eye, and you slow.
*goto pastabarrel

*label getready
*page_break
Your phone beeps with an alarm, alerting you that it's time to get ready.
*goto routine

*label pastasighted

Taking a moment to gather the essentials—phone, earpiece, keyring, worn out old satchel—you crack open the doors and step outside. Shutting them behind you, it's a simple task to lock everything back up. Once you're done securing your house, you turn around and immediately stop.

*label pastabarrel
A barrel sits in front of your shipping container, deliberately placed to be in direct view of the entrance. On top of it rests an innocuous plastic dish. @{earlyout Neither were there when you left.|You're certain neither were there last night.}

*if instinctive > 50
    You hesitate, and then walk over to the display.
    
*else 
    You edge towards the display with slow, deliberate steps.
    
Reaching the barrel without incident you take a closer look at the dish, which is sealed tight. It's filled with pasta. A handwritten note is attached to the lid:

[i]Hi.
Please help yourself. You can keep the container.
A friend.[/i]

You stare. There's even a little wooden fork taped onto the note.

…What?
*choice
    #That's... weird.
        This definitely wasn't in your predictions for today.
        
        You glance around the building. It's as abandoned as ever. No sign of anyone. Nothing out of place.
        *goto pasta
    #Is somebody onto me?
        Someone knows you've living here. That isn't supposed to happen. You could be compromised.
        
        Though what kind of hero or law enforcement announces themselves by dropping off a box of their home cooking?
        *choice
            #I don't know, but I can't do anything about it until later.
                Right; you have an appointment to keep. You're probably safe for now.
                *goto pasta
            #Pasta La Vista.
                *set alidisplay 2
                …Good grief.
                *choice
                    #...Anyway.
                        *goto pasta
                    #Torturllini.
                        …My goodness.
                        *choice
                            #Ahem.
                                *goto pasta
                            #Fettumeanie.
                                …[i]Wow.[/i]
                                *choice
                                    #Heh...
                                        *goto pasta
                                    #Revil-oli.
                                        …
                                        *choice
                                            #Okay that one was a reach. I'm done.
                                                Probably for the best.
                                                *goto pasta
                                            
    *if (earlyout) #Somebody put this here while I was on patrol...
        It's one part unnerving and one part frustrating. You must have missed them only narrowly.
        
        Unless, you reflect darkly, they were watching and waiting for you to leave.
        *goto pasta
*label pasta

Meanwhile, the pasta is still just sitting there.

Your stomach, with a sudden growl, reminds you that you've yet to eat today.
*choice
    #...Heck, I'll take it with me. What's the worst that could happen?
        It's pasta, not a hand grenade.
        *goto acquirepasta
    #This is definitely a trap.
        The food could be poisoned. Or conceal some kind of ingestible tracker. The dish itself might even be rigged up to blow. You can't tell, and you aren't going to take the risk.
        *goto rejectpasta
    #This might be a trap, but I'm hungry.
        Sure, on the one hand, the food could be poisoned or the dish somehow booby trapped, but on the other, you're probably not going to eat for hours otherwise.
        
        Also, whoever wrote the note knows where you live. If they wanted to hurt you then there are far less convoluted ways of going about it.
        *goto acquirepasta
    #I'm not touching that.
        Mystery pasta is too weird for you to take at face value. The safe option is to leave it alone.
        *goto rejectpasta
    #I hate pasta and all that it stands for.
        You glower at the dish.
        
        That'll show it.
        *goto rejectpasta
    #Free pasta!
        Sometimes life gives you mysterious pasta, and when life gives you pasta, you make—okay you don't make anything. But you don't reject it out of hand.
        *goto acquirepasta

*label acquirepasta
*set pasta true
*if instinctive >=35
    You scoop up the dish and find that it slots perfectly into your satchel. Nice. You're on a roll this morning. 
    
*else
    You scoop up the dish and, after a careful inspection to ensure that it's properly sealed and not about to leak everywhere, slot it into your satchel, where it fits perfectly.
    

*label rejectpasta
@{pasta With your unexpected windfall secured, you |You give the barrel and its dubious occupant a wide berth and }head for the industrial yard's gate. @{pasta |Your stomach mourns.}  Next stop, Architect and Wyrd. This shouldn't be too much of a trek.
*page_break Take a walk.

You make your way through Alderbrook's streets in comfortable anonymity. There's no sign of any heat from the Glory Hounds, unsurprising given that the six of them aren't nearly enough to launch a manhunt over what amounted to a petty robbery and a bloody nose. @{arcade_nose You smirk. Literally. |}Furthermore, while Alderbrook is similar to a great number of other cities in possessing an active lower tier of masked crimefighters, you doubt that any of them would dare to muscle in on Glory Hounds business.                         

Where Alderbrook differs from many—though not all—cities is its lack of DPR presence.

The government's Department of Parahuman Relations (or Regulation, as some scorn them) sponsors the majority of the country's superhero teams, as well as employing a sizeable force of ordinary but exceedingly well equipped officers. This, ahem, "Provides a unified and trustworthy face of justice to parahuman and unpowered alike!"

Yeah. Right.

In practice, there are plenty of DPR horror stories. After a half decade cut off from the news, the very first headline you saw was a statement from the current DPR chief running damage control on recent accusations of corruption in their ranks. Seems that some things never change.

As your feet carry you ever closer to your destination, some of those old stories start drifting through your head.
*label DPRmenu

*choice
    *hide_reuse #The stringent restrictions on DPR-sanctioned superheroes.
        *set dprthoughts +1
        Back in the day, it seemed as if one hero or another was in the news every month apologising for misconduct or getting slapped with fines for ridiculously minor infractions. Apprehend a villain in a way the DPR didn't like, skip out on a media appearance, or otherwise violate the DPR's exacting standards, and get pulled into a press conference for a whole dog and pony show. Once, one of the heroes local to your hometown had to issue a statement for swearing on camera. After getting put through a wall.
        
        Is it any wonder that a steady stream of heroes was constantly quitting on them?
        
        In all of one week, you've already confirmed that the exact same thing is still happening. You barely even had to look. For instance, two of the Glory Hounds are ex-DPR, including Enfilade, the augment you fought yesterday. The other defector is Phalanx, about whom you know precious little.
        
        Say what you like about the Glory Hounds—and you don't doubt the DPR says plenty—but they certainly seem to instil more loyalty than the sponsored teams.
        *goto DPRmenu
    *hide_reuse #Their mistreatment of parahuman suspects, even those not confirmed to be villains.
        *set dprthoughts +1
        Shortly before… everything, a story making the news cycles was the DPR violently detaining a teenaged parahuman under suspicion of involvement with a jewellery heist. From your understanding, the DPR barely had anything on her, just circumstantial evidence and a vaguely-plausible theory of how her power could have been used in the crime. Although she was released after a week, the situation swiftly turned into a scandal when the press caught wind of the terrible conditions of her custody and the severe injuries inflicted in the process of her arrest.
        
        Last you knew, the DPR was preparing to shell out a boatload of cash to pay the problem into disappearing.
        *goto DPRmenu
    *hide_reuse #The massive turnover in DPR officers.
        *set dprthoughts +1
        The DPR was always churning through its unpowered personnel like a thresher, and you doubt that's changed in the last few years, not unless they stopped throwing their officers to the wolves against supervillains. Even though most villains knew better than to slaughter them wholesale, DPR officers were still bringing containment weaponry to a superpower fight.
        
        There's something admirable about the willingness to go toe to toe with a superior opponent—who does that remind you of?—but despite all of their gear, some threats are truly out of the league of the average DPR squad.
        *goto DPRmenu
    *hide_reuse #Those rumours around their Agent program.
        *set dprthoughts +1
        The government slash DPR sponsoring augments is nothing new. Heck, it's about the only route to augmentation that doesn't require a mountain of money, enough black market connections to make an arms dealer blush, or the special type of bravery reserved only for the suicidally confident or the utterly insane.
        
        Agents are the DPR's personal augments, and the horrific rumours about them get into the territory of boogeymen and urban legends. Volunteers falling off the grid, people snatched in the night for experiments, procedures gone wrong and then covered up. Whenever someone in the parahuman sphere dies or vanishes under unknown circumstances, Agents are the first to get the blame.
        
        You don't know if any of it is true, but you've seen video that the uploader claimed was a real life Agent. In the shaky footage, a blurry figure mercilessly butchered a group of criminals, shrugging off gunfire like a minor inconvenience. The violence was so brutal that you had to stop watching within thirty seconds.
        
        Even all these years later, with firsthand experience of some terrible sights, that footage sticks with you still.
        *goto DPRmenu
    *if (dprthoughts < 4) #These stories aren't relevant right now.
        Places to be and people to see, right?
    *if (dprthoughts = 4) #Anyway, I should move on.
        *set fulldpr true
        Though it's always nice to remind yourself that you haven't lost all recollection of the outside world. In a way it's reassuring that there's consistency after all this time. 
        
        
@{fulldpr In that same vein, you|Even so, you do} find yourself briefly reflecting on your own old opinions on the DPR.
*choice
    #I didn't trust the DPR even before I became parahuman.
        *set dpr 1
        Anyone who wants the kind of control the DPR exerts is bad news in your book.
        
    #To me, the DPR was in kind of an impossible position, and doing what they could.
        *set dpr 2
        The DPR's thankless task was and is to deal with, on a day to day basis, threats that are fully capable of levelling buildings and slaughtering dozens if not hundreds of people. While simultaneously attempting to wrangle the egos of allies who happen to hold those exact same capabilities. It's the definition of a no-win situation and you don't envy them for a second.
        
        Except for the part where they have the option to quit. You might envy them that.
        
    #There wasn't really much reason for me to think about the DPR.
        *set dpr 3
        You weren't parahuman and your old town was fairly quiet so far as marauding masks went.
        
        A bitter smile tugs at your lips.
        
        Well. So you thought.
        
    #Fuck the government.
        *set dpr 4
        The DPR is just another part of a thoroughly corrupt, outdated, and inept system that does more harm than good.
        
        It's no surprise when a rotted tree has a twisted, diseased branch now, is it?
        
        *if motive = 1
            Maybe what you told Architect and Wyrd about bringing down the system wasn't 100% a lie.


Regardless, from what you've been told Alderbrook has long been a no go zone for the DPR. The Glory Hounds are popular, charismatic, and most importantly get the job done. Success goes a long way to quell any anxieties that could have the locals seeking out the stability of DPR's aegis.

Your pace slows as the street and sidewalk ahead of you are blocked off by bright orange security barriers. Dozens of bold warnings proclaim DO NOT APPROACH and UNSTABLE GROUND. You've reached the Zone. Beyond those barriers the street, along with several buildings, simply plunges into a chasm almost 100 feet deep. The nearby buildings spared the sinkhole itself range from partially destroyed to piles of rubble. The better part of two entire blocks ravaged by rampant masked violence.

The Zone is a monument to the Hounds' failure, the consequence of a mission gone badly wrong. Eighteen months on, the city is barely beginning to reassemble the broken pieces.
*page_break

Today, skirting the Zone just adds ten minutes to your trip. On a wider scale, the screw up the Zone represents means that for the first time in years, there are DPR officers in Alderbrook. As success quells anxieties, so too does catastrophic failure stoke them to a fever pitch. Even so, the handful of personnel assigned to the city shouldn't be able to trouble you. According to $!{cg}, who briefed you on the Zone in the first place, the DPR's jurisdiction here is extremely limited.

Step by step, you pass by the destruction.

*if (pasta)
    As you walk, you decide to crack open the pasta and have a sample. This pretty much counts as breakfast right? Not like you'd have eaten otherwise.
    
    You take a stab with the convenient fork and eat an experimental mouthful.
    *fake_choice
        #It's good.
            Oh damn. This is the good stuff.
            
            @{alidisplay Mysterious pasta person|Pasta La Vista|DUMMY} sure knows their way around the kitchen. Unlike anyone who has fed you in the last five years. Even if you wanted to try eating a little better and could afford more than the bare minimum of ingredients, your container isn't equipped for home cooking.
        #It's annoyingly good.
            How the heck is the best meal you've had in
            
            Uh.
            
            An unspecifically long time.
            
            How the heck is the best meal you've had in ages the random mystery pasta inexplicably left on your doorstep?
        #It's bad. (This is a lie).
            You stubbornly refuse to acknowledge how good the pasta tastes even as you go in for another forkful.
            
            No, you won't be swayed by mystery doorstep pasta!
            
            Unfortunately, your inner food critic has subsisted on snacks and whatever you can scrounge from discount aisles that doesn't require cooking for the past week. And the less said about the fare of the previous five years the better. Despite your best efforts, you can find nothing to criticise.

*else
    Your stomach groans again. You're beginning to regret a little not nabbing the pasta while you had the chance. Suspicious circumstances notwithstanding, it would probably have been better than the meagre fare that's all you're able to scrape together at present. Almost definitely better than what you were forced to live off in the Coven these last five years.
    
    Still, you shouldn't second guess yourself just because you're hungry. You chose to leave the dish alone for a reason.
    
*page_break

@{pasta Freshly fuelled by your snack, which you reluctantly put away,|Spurred on by hunger pangs} it's not too much longer before you reach the address Architect gave you. This neighbourhood is only a few blocks away from the first safehouse and has maybe twenty percent fewer boarded windows. Not exactly upscale.

Still, the building you enter is still an upgrade on yesterday by virtue of possessing an actual front door.

Checking your phone to confirm that you're on time—slightly early as it happens—you pause in the entry hallway and take stock of yourself. This is your last opportunity to rehearse your cover. Your try to fix $!{cg}'s prepared lines at the forefront of your mind, ready to leap naturally in response to anything the two parahumans might ask. They can't be allowed to suspect you.

Here goes nothing. The address is on the second floor. You take the stairs up. A short hallway on your left leads to a door labelled 201. Your destination.

Two steps down the hall you begin hearing muffled voices from within, and pause.
*choice
    #What am I waiting for? Go ahead and knock.
        Walking up, you rap confidently on the apartment door.
        
        The conversation halts immediately.
        
        "It's open! You can come in!" calls a voice.
        *page_break
    #They're expecting me. I'll stroll straight in.
        *set stroll true
        *set instinctive %+ 3
        Why knock when you've already agreed a time and a place? You walk up to the apartment door, open it, and step inside like you own the place.
        
        Within, Architect stands in a small kitchen area, leaning forward on a counter while Wyrd lounges opposite him in what appears to be the apartment's singular chair. The latter is speaking as you enter. "—just saying, man, that whole thing cut pretty close to—ohhhh hey there!" Wyrd slams the brakes mid-sentence, popping straight up onto their feet. Recognition seems to hit a moment later, and they flash you with a grin.
        
        "Hi," you reply, taking a quick glance around the room. There isn't much to see, and while the furnishings are a mild improvement over yesterday's derelict safehouse, the entire arrangement screams temporary. Both parahumans are dressed casually, which means a change of clothes for Wyrd and a total transformation for Architect.
        
        "Aren't you an eager beaver?" says Wyrd. "Guess you already feel like part of the gang, waltzing in like that." They wink. Now that you're paying closer attention to them, you're a little thrown. They look surprisingly different. For one they seem slightly shorter; are they slouching? Plus, their features don't quite match up to your memory. Sure, they're not wearing the domino mask any more, but it feels strange that something so simple could have such an impact.
        
        Architect clears his throat. "What Wyrd means to say is welcome." He meets your eyes levelly and smiles, polite and cool. Beneath the helmet and divested of the longcoat, he turns out to be a man in perhaps his late twenties. His skin is dark with warm undertones, his hair worn in a short afro fade as immaculate as his well-trimmed beard. Somebody spends a lot of time maintaining his hair. @{natural You feel a brief pang of envy, which you shake off to reply.|You consider your reply.}
        *choice
            #"Thanks, happy to be here."
                *set rel_wyrd -2
                *set rel_architect +2
                "You [i]are[/i] an eager beaver," Wyrd says with a grin. "Employee of the month incoming."
                
                Architect shoots them a look you can't place, and then returns his eyes to you. "Well, shall we get to introductions?"
                *page_break Right.
                *goto makingintroductions
            #"Yeah, I expect to be put in charge immediately."
                *temp incharge true
                *if expressive < 30
                    *set expressive +3
                    *set rel_architect +2
                    For a couple of seconds, they both just look at you, and you try not to squirm under the scrutiny. Aren't jokes supposed to be good icebreakers? Did you say it wrong?
                    
                    Then Wyrd starts cracking up. "Man did—" they break off for a fit of chuckling. "—Did anyone ever tell you that comedy is in the delivery?"
                    
                    Feeling awkward, you look down and shuffle your feet.
                    
                    "Be nice," Architect scolds gently. "We're supposed to be making introductions."
                    
                *else
                    *set rel_wyrd +2
                    You deliver the line with what you judge as the perfect ironic drawl.
                    
                    Wyrd grins, and you know you've nailed it. "Well, you heard 'em, Architect. About time we had some new blood at the top around here."
                    
                    "Oh, be quiet."
                    
                    "I don't take orders from you anymore."
                    
                    Architect rolls his eyes. "Let's not get sidetracked. We're supposed to be making introductions."
                *page_break Right.
                *goto makingintroductions
                   
            #"Hey, if you're going to leave your door unlocked..."
                *set rel_wyrd +1
                *set rel_architect +1
                Wyrd snorts. "You got us there."
                
                Architect makes a non-committal noise.
                
                "S M H, get better locks." Wyrd enunciates each letter of the acronym. They don't actually shake their head.
                
                Architect rolls his eyes. "Let's not get sidetracked. We're supposed to be making introductions."
                *page_break Right.
                *goto makingintroductions
    #I'm here for information. I try to eavesdrop from outside the door.
        *set instinctive %- 3
        
        *if subterfuge >= 35
            Lightfooted, you approach the apartment door, halting half an inch from touching. Tilting your head at the best angle, you strain to make out what's being said.
            
            "—just saying, man, that whole thing cut pretty close to the line." That's Wyrd, you're pretty sure.
            
            "It was only a threat." Architect sounds slightly different. It takes you a moment to put a finger on the change, but you realise you're probably hearing him without his helmet.
            
            "Yeah? And what if she called your bluff?"
            
            "Surpass would never do that."
            
            "Says you."
            
            "I knew what I was doing, Mallory."
            
            A heavy sigh. "Yeah yeah. You always do, don't you?"
            
            The conversation lapses. You hang around for another ten, twenty seconds, but it seems like that's as much as you're going to get.
            
            You give the door a knock.
            
            "It's open! You can come in!" calls a voice. Architect.
            
        *else
            You creep up to the apartment door, treading as lightfooted as you can.
            
            However, as you approach to within a couple of feet, you scuff your shoe on the floorboards and stumble.
            
            You catch yourself before you trip, but the conversation inside immediately halts.
            
            "Hello? Door's open! You can come in!"
            
            Dammit. No dice. Adjusting your satchel, you cross the remaining distance normally and open the door.
            *page_break

Stepping inside, you find the two of them waiting for you. Architect stands in a small kitchen area, leaning forward on a counter while Wyrd lounges opposite him in what appears to be the apartment's singular chair. The furnishings are a mild improvement over yesterday's derelict safehouse, though the entire arrangement screams temporary. Both parahumans are dressed casually, which means a change of clothes for Wyrd and a total transformation for Architect.

Beneath the helmet and divested of the longcoat, Architect turns out to be a man in perhaps his late twenties. His skin is dark with warm undertones, his hair worn in a short afro fade as immaculate as his well-trimmed beard. Somebody spends a lot of time maintaining his hair. @{natural You feel a brief pang of envy. Architect|He} meets your eyes levelly and smiles, polite and cool.

Once you actually attend to Wyrd, you find that they look surprisingly different. They seem a little shorter; are they slouching? Their features don't quite match up to your memory. Sure, they're not wearing the domino mask any more, but it feels strange that something so simple could have such an impact.

They're also much more eager than Architect, popping straight up onto their feet.

"You made it! How the heck you doing?"
*fake_choice
    #"I'm fine."
        "Nice, nice."
    #"Great! How about you?"
        *set expressive %+ 5
        "Me? I'm amazing." They wink. "And I'm doing great."
    #"Depends on how this shakes out."
        *set instinctive %- 5
        They huff a short laugh. "You sound like D—Architect."
    #Shrug noncommittally.
        *set expressive %- 5
        A small, unreadable smile plays across their face. "Fair enough."
        
"Afternoon." Architect speaks. "Good to have you here."

*label makingintroductions
*if instinctive < 40
    You nod, and then hesitate. "I admit, I haven't done anything like this before. Is there some kind of protocol…?"
    
*else
    You nod, and then glance between the two of them. "So, how does this work? Do we go around the room and share a fun fact about ourselves?"
    
*set wyrdisplay 2
*set archdisplay 2
Part of your cover is that you're a lone operator with no experience of teaming. Fewer moving parts to track that way. For instance, there's no need to fabricate past associates or explain your lack of history. Plus, it's partway true. The Coven isn't any kind of regular villainous outfit.

Architect smiles again, warmer than before. "Well, for starters, my name's Dion."

Wyrd launches their hand into an excessively exuberant wave. "Mallory. Call me Mal, everyone does." Without pause, they hold a finger aloft. "Oh and I use pretty much whatever pronouns. Go nuts."

The pair regard you expectantly, and you have an important decision to make.

Are you going to give them your real name?
*choice
    #Yes.       
        Why?
        *label realname
        *fake_choice
            #It would be nice to feel like a person for once.
                *set seethe +2
                Even now, you're beholden to others. You're here because it's permitted—not even permitted, demanded.
                
                Using your name. It's a spark of self-determination and freedom. The tiniest ember of getting to be yourself, on your own terms.
                
                Something to warm you, if only for a short while.
                
            #I... don't know. I just want to.
                *set loyal +1
                You shouldn't. You know that you shouldn't.
                
                It's just that in this exact moment, 'shouldn't' doesn't seem to hold that much of a grip on you.
                
                You're telling them your name because it's what you want to tell them.
                
            #I just want to hear my name again.
                *set break +2
                Maybe you're dwelling on the past too much after that nightmare. It's over five years since anyone called you $!{mc_name}.
                
                You can't even remember who said it last.
                
                Is it so wrong to want to hear a simple '$!{mc_name}' outside the bounds of distant, faded memories?
                
            *if (not(choice_randomtest)) #On second thoughts, I'll come up with an alias.
                *goto alias
        *set namedisplay 4
        *set aka mc_name
        
        *if (nickname)
            *set aka2 forename
            
        *else
            *set aka2 mc_name
        *goto givename
    
    *if (not(choice_randomtest)) #No.
        Why?
        *label alias
        *fake_choice
            #It's easier to keep the story straight this way.
                *set seethe +1
                You're playing a role. Assigning a name to that role gives you an active reminder of who you're supposed to be.
                
                Not $!{mc_name}, but someone else.
                
                After all, don't they call you Paradigm?
                *input_text aka
                *goto namecheck
            #That's not my name any more.
                *set break +2
                It's in the past. A lot of things are in the past.
                
                This way, it'll be easier when the name's stripped away and you go back to being solely Paradigm.
                *input_text aka
                *goto namecheck
            #Otherwise, I'm risking blowing my cover.
                *set loyal +2
                Although it's unlikely anyone could connect the dots between you and your past—that was years ago and not even in Alderbrook—there's nothing wrong with exercising caution.
                
                Messing this up would be… bad.
                
                Yeah. Bad.
                *input_text aka
                *goto namecheck
            #I've changed my mind. I'm giving them my real name.
                *goto realname
    
*label namecheck
*set pseudonym true
*if ((aka = forename) or (aka = mc_name))
    That's… your real name.
    *page_break Oh, right.
    *input_text aka
    *goto namecheck
*elseif ((aka = "Dime") or (aka = "Paradigm"))
    There's no world in which that is a good idea.
    *page_break Think of something else.
    *input_text aka
    *goto namecheck
*elseif (((aka = "Prii") or (aka = "Grant")) or (aka = "Shauna"))
    *label dothat
    You couldn't possibly do that to $!{aka}.
    *page_break Think of something else.
    *input_text aka
    *goto namecheck
*elseif (aka = "Beth")
    *if (nickname_salt > 0)
        That name's tainted now.
        *page_break Think of something else.
        *input_text aka
        *goto namecheck
    *elseif (ranaway) or (battitude = 1)
        *goto dothat
        
    *else
        *if (battitude = 2) or (battitude > 3)
            Do you really want to name yourself after someone you're so messed up over?
            *goto mny
            
        *elseif (battitude = 3)
            Despite your usual numbness towards Beth, the idea of taking on her name sends a distinct feeling of discomfort through you.
            
            *label mny
            *page_break Maybe not.
            *input_text aka
            *goto namecheck
                   
*else
    You're going with the alias $!{aka}, right?
    *choice
        #Yes.
            *set aka2 aka
            *goto givename
        *if (not(choice_randomtest)) #Actually, it's...
            *input_text aka
            *goto namecheck
        
*label givename
*if ((nickname) and (not (pseudonym)))
    "I'm $!{forename}. $!{mc_he}/${mc_him}," you tell them. "You can call me $!{aka} though." Your own name sounds strange on your lips. There's a lump in your throat.

*else
    "I'm $!{aka}. $!{mc_he}/${mc_him}," you tell them. @{pseudonym You keep your voice firm. You can't let anything slip.|Your own name sounds strange on your lips. There's a lump in your throat.}
    
"Then it's good to meet you for real, $!{aka2}," Dion replies. @{pseudonym You burn the sound of your assumed name into your memory. You need to respond to it naturally.|Something twinges deep in your chest. You fake a cough, raising your arm to hide the tears springing to your eyes. Dammit. You shouldn't let this affect you so much.}

@{pseudonym "Likewise."|"Sure," you manage.}

Mal raises both hands, index fingers extended. "Oh yeah! We're kind of doing this backwards but whatever. Somebody forgot to ask your mask name yesterday."

"You didn't ask ${mc_him} either, Mallory," Dion protests, looking surprisingly embarrassed.

"Sure, but I'm the irresponsible one, so I'm allowed."

Dion frowns, and then sighs, shaking his head. "At least you admit it." He turns his attention to you. "As Mallory was saying, we don't have a name for you in costume."

Ah. Time to unveil your superpowered identity. The nom de guerre for your masked activities. You've thought long and hard about this.
*label nameselection

The name you tell them is:

*choice
    #Thorn.
        *set mask "thorn"
        *goto mynameis
    #Thresh.
        *set mask "thresh"
        *goto mynameis
    #Manticore.
        *set mask "manticore"
        *goto mynameis
    #Chironex.
        *set mask "chironex"
        *goto mynameis
    #Paradigm.
        *set mask "paradigm"
        *goto paradigm
    *if (not(choice_randomtest)) #[Input my own name]
        *input_text mask
        *goto mynameis

*label mynameis
*if (((mask = "Hypothesis") or (mask = "Catalyst")) or (mask = "Coven"))

    That's… an incredibly bad idea.
    
    Yeah, no. You're going to need to pick something else. You don't have a death wish.
    *page_break Reconsider.
    *goto nameselection

*elseif (((mask = "Surpass") or (mask = "Arcade")) or (mask = "Enfilade"))
    
    Funny, but also the kind of thing that gets you onto the heroes' shitlists.
    
    *page_break Reconsider.
    *goto nameselection

*elseif ((mask = "Paradigm") or (mask = "Dime"))
    *goto paradigm

*elseif ((mask = "Wyrd") and (shenanigans))
    *set rel_wyrd +1
    *set shenanigans false

    "Ha! You've got great taste." Mal tips you an elaborate wink. "Seriously though."
    *choice
        #I tell them...
            *input_text mask
            *goto mynameis
        *if (nickname_salt = 1) #I cannot freaking believe this has happened twice.
            Forget the whole 'if I had a nickel for every time…' routine. This is total bullshit.
            *choice
                #Cope, seethe, and give them a different name.
                   *input_text mask
                   *goto mynameis

*elseif ((mask = "Architect") and (shenanigans))
    *set rel_architect -1
    *set rel_wyrd +2
    *set shenanigans false
    
    "Hmph." Dion narrows his eyes at you.
    
    Mal, by contrast, is smothering a laugh. "Okay, but seriously?"
    *choice
        #I tell them...
            *input_text mask
            *goto mynameis
        *if (nickname_salt = 1) #I cannot freaking believe this has happened twice.
            Forget the whole 'if I had a nickel for every time…' routine. This is total bullshit.
            *choice
                #Cope, seethe, and give them a different name.
                   *input_text mask
                   *goto mynameis
               
*elseif ((mask = "Architect") or (mask = "Wyrd"))
    "Uh huh. But really?"
    *choice
        #I tell them...
            *input_text mask
            *goto mynameis

*else
    *goto nameconfirmation


*label nameconfirmation
*if ((mask = "Skitter") or (mask = "Sidestep"))
    You feel like you read that name somewhere before.

You'll be going by $!{mask}, correct?
*choice
    #Yes.
        *set masknamed true
        *goto namechosen
    *if (not(choice_randomtest)) #No.
        You tell them:
        *input_text mask
        *goto mynameis
  
*label paradigm
*if mask = "paradigm"
    Paradigm… the selfsame name they gave you in the Coven.
    
*else
    Dime. A shortening of the name they gave you in the Coven, and what passes for your nickname these days.

Although that part of your identity is very much a secret, using $!{mask} as a name still runs the risk of blurring the lines between that life and your undercover activities.

You're also on the hook for reports; $!{cg} will want to know your mask name as soon as possible. There's absolutely no way that this stunt doesn't get back to the whole Coven, and there's absolutely no way that the reception will be positive. Coven secrets aren't to be flouted.

With all that in mind, are you still going with $!{mask}?
*choice
    #On second thoughts...
        *goto nameselection
    #Yes I am.
        *set diming true
        Why is that?
        *choice
            #It's a small act of rebellion.
                *set seethe +1
                Rarely do you have any opportunity to tug against the chains binding you.
                
                Maybe this is false freedom, but even a facsimile is better than a cage.
            #I suppose it's a self-destructive impulse.
                *set break +1
                You've walked this path before. Acting in ways that will only hurt you in the end.
                
                That doesn't stop your feet from tracing those same steps over and over again.
            #All of my other ideas were terrible.
                *set loyal +1
                
                Sure, you thought long and hard about potential names. That doesn't mean it was productive.
                
                Part of you hoped that you'd come up with something better all the way up until this exact moment. Alas it's the moment of truth and no bolt of inspiration has struck.
                
        $!{mask} it is.

*label namechosen
*if (mask = "Dime")
    "Dime?" Mal grins. "We talking like ten cents or like dropping dimes?"
    *choice
        #"...What?"
            The smile slides a little. "Nevermind." 
        #"Ten cents."
            *if motive = 3
                Mal snorts. "Guess you did say you were here for the money."
                
            *else
                Mal snorts. "Think you can set your sights on slightly bigger scores than that, $!{aka}."
                
        #"Dimes, absolutely."
            *set rel_wyrd +1
            Their eyes glitter. "Love it."
        #"It doesn't really mean anything."
            They look mildly disappointed. "Darn."
        #"I uh, I don't watch soccer."
            "Soccer? That's not—" Mal stops, shoulders slumping. "Oh nevermind."
*else
    "$!{mask}, huh?" Mal says thoughtfully. "Nice. I like it. Has pop."
    
Now fully acquainted, you glance between the pair. "What comes next?"

Leaning down, Dion produces the briefcase you helped secure from behind the counter. "Do you know what type of business we hit yesterday, $!{aka}?"

*if knowledge > 30
    You nod, having gleaned that information as you searched for a route into the building. "Sure. It was a loan shark."
    
    "Exactly. This briefcase belonged to one of their biggest leeches."
    
*else
    You shrug. "I didn't stop to check."
    
    "It was a loan shark. This briefcase belonged to one of their biggest leeches."
    
    
"So you stole a bunch of paperwork?"

Dion laughs. "More or less. We'll be able to crack into a bank account or two for some extra cash, but that wasn't the main goal." 

Mal picks up the thread. "We've had feelers out with a couple of locals. Some of their folks are in trouble with the sharks, and we agreed to take care of the problem."

You put it together. "Which meant robbing the office."

Mal winks. "Nailed it. Trashed their computer systems too. It'll be months before those scumbags can exploit anyone else."

"To circle back to the original question, $!{aka2}, now we're going to meet our new friends to give them the good news and ask them to hold up their side of the deal." Dion meets your eyes steadily. "Any questions?"

You consider for a moment.
*label questionsmenu
*choice
    *hide_reuse #"These locals, what can you tell me about them?" I'm curious about who we'll be meeting.
        *set archquestions +1
        "They're like…" Mal laughs. "What's the level below smalltime? They're that."
        
        Dion shakes his head. "Mal means that they aren't masks. Yet. We're looking to bring them aboard."
        
        You cock your head quizzically. "How do you know about them if they're not masks?"
        
        "Trade secret," Mal quips.
        
        Dion rolls his eyes. "I have a contact in the area. I asked them to keep me informed of any potential recruits."
        
        You nod. Makes sense.
        
        *goto questionsmenu
    *hide_reuse #"Aren't you trusting each other an awful lot?" Enlisting strangers seems very risky.
        *set trust true
        "Occupational hazard," Dion replies.
        
        Mal nods for emphasis. "A lot of parahumans live under the radar. Way too many for the likes of the Hounds to keep an eye on all of them; even the DPR can't pull that off."
        
        "Exactly," says Dion. "For their part, this mission further proves our good faith. On the other side of the equation…" Dion turns both palms upward in perhaps the smallest shrug you've ever seen. "I'm not fooling myself. We aren't big fish. We aren't even moderate fish. We're a couple of guppies in a medium pond. It's not worth the heroes' time to go undercover and lay traps for any but the biggest fish in the sea."
        
        You hope to hell that your poker face is intact. Sure, going undercover isn't worth the [i]heroes'[/i] time…
        
        "Otherwise, it's honour among thieves." Mallory grins, seeming to enjoy that idea. "If we screw them, they screw us, and vice versa. Besides, the Hounds aren't really known for cutting deals with villains. Their rep relies on beating the bad guys, not negotiating them to death." They wink. "Lucky us, right?"
        
        *goto questionsmenu
    *hide_reuse #"Are we expecting any trouble?" If a fight's going to happen, I want to be ready for it.
        *set archquestions +1
        "No," Dion answers. "So far as the heroes are concerned, a reliable source tells me that they're looking to smack down the Shreds before they stir up any more trouble. The Hounds will be much too busy with that to interfere with us while we're out of costume. On our side, we're meeting our new friends and that's it. If they decide to back out on their end of the bargain, I'm not interested in escalating the situation."
        
        A question immediately springs to mind. "Won't that hurt your reputation? People will start thinking they can take advantage."
        
        Dion inclines his head. A fraction of an inch. "True, $!{aka2}, but we got our hands on enough of the shark's files that we'd still come out more or less ahead."
        
        "Financial crime is best crime," Mal adds, nodding sagely.
        
        "I don't think that counts as financial—" Dion stops himself with a long-suffering sigh. "Never mind."
        
        Mal grins from ear to ear.
        
        *goto questionsmenu
    *if ((archquestions = 2) and (observation > 20)) 
        *hide_reuse #"You seem to be well-connected." He's mentioned contacts twice now.
            *set archconnections 1
            *set archinfo 1
            *if subterfuge < 20
                *set doubt_architect +5
        
            You try to sound casual rather than probing. For a new villain in town, and one with very little known history, Architect sure seems to have tapped quickly into local information networks.
        
            "I have my ways," says Dion. Is it your imagination that his casual tone sounds almost… rehearsed?
        
            Mal scoffs. "Don't let Dion fool you with the Mr. Mysterious act, $!{aka}. We knew the town before we ignited, so he knows where to flash the cash. Little goes a long way with the right people."
        
            *if subterfuge < 20
                "Just drag our history into the open why don't you?" Dion grumbles. His eyes flick from Mallory to you, just for a moment, leaving an uncomfortable impression of scrutiny.
            
            *else
                "Just drag our history into the open why don't you?" Dion grumbles, narrowing his eyes at Mallory.
            
            Mal shrugs lackadaisically. "$!{aka} asked, and it's not like it's all hush hush."
        
            "Sorry, I didn't mean to pry," you say, but you're turning the conversation over in your head. Something doesn't sit right.
        
            One thing's for sure, they definitely know more about Alderbrook than the Coven thought. Worth reporting.
        
            *if seethe >= 3
                Or worth keeping to yourself, muses a rebellious thought that you swiftly quell.
            
            Probably best to leave it here though.
            *page_break
            *goto doneasking
    #There's nothing else I want to ask.
        *label doneasking
        *if expressive > 70
            "No more questions, your honour."
        *else
            "I'm finished."
        
"Excellent." Dion studies you. "May I ask you something, then?"

Ah. You were wondering when the scrutiny would start. You nod.

"There are other outfits in Alderbrook. Better established outfits. @{trust You asked about trust just now. Well, why is it that you're choosing to trust us?|Why are you putting your trust in us and not them?}"

Luckily you're prepped for this one.

"The other villains here don't meet my standards," you reply, then begin ticking off on your fingers. "S.C.U.M are a bunch of psychopaths. The Shreds are pretty much a cult; I'm not working with people who use unpowered folks as foot soldiers. @{money I could probably make some money with the Businessmen, but if I wanted to get buried in middle management, I'd go back to my 9 to 5.|The Businessmen only care about their bottom line, and that's not why I'm here.}" You pinch a fourth finger. "That just leaves a couple of independents or striking out on my own." Curling your hand into a fist, you meet Dion's eyes. "Then there's you guys. Brand new on the scene and already making a splash. That got my attention. You're starting something, and I want in on the ground floor."

Dion regards you with a long and thoughtful look. "And what has you so convinced?"

*if instinctive >= 55
    "Actually I'm still reserving judgement." You shrug. "But I do have a good feeling. Call it gut instinct."
    
    "I see."
    
*else
    "Oh, don't get me wrong. I'm still reserving judgement," you tell him. "For now, I'm trusting that you turn out better than the rest of them."
    
    Dion nods. "That's reasonable."

"Ooh, my turn!" Mal breaks in, catching both of you off guard. @{fighting_style "You've got some moves when you fight. Where did you pick them up?"|"You're pretty sharp in a fight. How'd you pick that up?"|"I know expertise when I see it. How'd you get so good with your powers?"|DUMMY}

That's a little more complicated, but you do have a cover. $!{cg} suggested that you kept the details light and leaned on your personality to sell it, rather than coming up with any elaborate deceptions.

*if (fighting_style = 1)
    *choice
        #"I've done Muay Thai for a while. Needed an outlet for my frustrations, you know?"
            *if expressive < 50
                *set doubt_architect +5
                *set doubt_wyrd +5
                "An outlet? You?" Mallory is incredulous.
                
                "Well… yeah," you answer awkwardly.
                
                They laugh. "Okay maybe you've got this hidden reserve of anger I don't know about but you don't really come across as the 'ragh vent my rage on the heavy bag ragh' type, $!{aka}."
                
                Dammit. "That's because I work that side of me out at the gym," you say, trying to regain your footing in the conversation.
                
                Mal tilts their head to the side. "If you say so."
                
                You're not sure they bought it.
                *goto covera
                
            *else
                "Ooh. Yeah. I get it." Mallory thumps their knuckles into their opposite palm.
                
                "Turns out you can learn a thing or two even if you started attending just to hit stuff," you add, smiling thinly. The best part of this story is that it's not fully a lie. Practicing Muay Thai with $!{cg} has been pretty darn cathartic. Too bad it's only a chip off the mountain you have to work through.
                
                "Remind me not to spar with you," says Dion. "Hand-to-hand isn't my scene."
                
                "I'll go easy on you." The smile on your face grows a little.
                
                Dion laughs and shakes his head. "In my experience, my definition of easy is always some distance from my opponent's."
                *goto coverb
        #"There's not much to tell. Gyms are a good environment to practice discipline."
            *if expressive >= 50
                *set doubt_architect +5
                *set doubt_wyrd +5
                Mallory looks at you askance. "Discipline? You?"
                
                "Sure," you answer, feeling a prickle of alarm.
                
                "Okay maybe this is just that we haven't known each other long, but you don't really come across as the zen, 'my mind is a fortress' type, $!{aka}."
                
                Dammit. "Maybe give it some more time then. Don't judge a book by its cover and all."
                
                "Fair enough." Mallory smiles. It doesn't quite reach their eyes.
                *goto covera
            *else
                "Oh yeah, makes sense." Mallory… you're not quite sure how to describe what they're doing. They close their eyes, take a deep breath, and then let it out, pushing their hands out in front of them.
                
                "Mallory. What was that?" Dion thankfully spares you asking.
                
                Mal opens their eyes and grins. "You know, zen mode. $!{aka}'s that kind of ${mc_guy}."
                
                "I… fine. You know what? I'm leaving that one alone." Dion shakes his head.
                
                You suppress a smile. They've sold it to themselves without you needing to so much nudge them along.
                *goto coverb
        
*elseif (fighting_style = 2)
    *choice
        #"Would you believe I was the shotcaller for my paintball team?"
            *if instinctive < 50
                *set doubt_architect +5
                *set doubt_wyrd +5
                Mallory smiles, showing teeth. "It's a hard sell."
                
                Ah dammit. "Well, I was," you say, because switching tack would be much worse.
                
                "I can't say it's the first hobby I'd have guessed for you," says Dion. "Still, our history doesn't always take the expected path, does it?"
                
                "Yeah, something like that," you reply, hoping you don't sound too eager to snatch the lifeline.
                *goto covera
            *else
                "Oh, paintball? Nice." Mallory looks genuinely enthusiastic.
                
                You nod. "It doesn't compare to superpowered fighting of course, but I guess it's muscle memory."
                
                "Tactics are tactics," agrees Dion. "That's a useful skill to develop."
                
                "I guess I know who I'm calling if I want to paint the town red," says Mal, winking.
                
                Dion groans. "Is it too late to turn you in to the authorities?"
                *goto coverb
        #"I guess I've always been a thinker. Preparation helps me have backup plans."
            *if instinctive >= 50
                *set doubt_architect +5
                *set doubt_wyrd +5
                Mallory looks at you askance. "Sorry, you're a thinker?"
                
                "Well, yeah," you reply, affecting a casual tone.
                
                A slightly bemused smile plays across their face. "Not the word I'd use."
                
                You shrug, even as your heartbeat quickens. Right… you've not come off as particularly prepared. "You'll see."
                
                "Yeah, maybe." They don't sound convinced. Dammit.
                *goto covera
                
            *else
                Mallory tilts their head to the side. "Not sure how that translates to combat."
                
                "It's about covering the angles ahead of time," you explain. "If I've already thought through what could happen, it's a lot easier to react."
                
                "I understand," says Dion. You hide a smile. You've got him. "It's informed improvisation."
                
                Mal makes a face. "I guess, but you don't just go from 'I want to be ready for this job interview' to 'I'll run circles around two top masks', right?"
                
                You shrug. "Let's just say the other kids at camp hated playing capture the flag against me."
                
                They laugh. "Okay Dion, if we hold any team-building exercises, I call shotgun on $!{aka}."
                *goto coverb
                               
        
*else
    *choice
        #"It comes naturally. I listen to what they're telling me, and I act."
            *if instinctive < 50
                *set doubt_architect +5
                *set doubt_wyrd +5
                *set lapping true
                "Huh…" Mal gives you a dubious look. "Wouldn't have put you as the 'feel, don't think' type, $!{aka}."
                
                "It's not that," you hasten to shore up your story. "It's more, you know, following the paths my powers already seem inclined towards."
                
                "Right, right. I guess that makes sense."
                
                You're not sure they bought the explanation. Dammit.
                *goto covera
            *else
                "Makes a ton of sense," says Mal, nodding easily. "I know I didn't really get a handle on my powers until I stopped overthinking and just let them flow."
                
                "Your powers?" you ask, because $!{cg} also taught you that diverting conversations is a good way to maintain your story. "It's not just the durability?"
                
                "Nope," Mal replies. They wink, then grin. "As for the rest… can't an enby have their secrets?"
                
                Dion rolls his eyes. "It's not a secret, you just love lapping up people's reactions when they find out."
                
                Mallory laughs. "Guilty."
                *goto coverb
        #"It's not easy. I have to practice a lot, keep my control tight."
            *if instinctive >= 50
                *set doubt_architect +5
                *set doubt_wyrd +5
                Mallory gives you a dubious look. "You don't strike me as the measured type, $!{aka}."
                
                "That's because I practice," you tell them quickly, hastening to shore up your story. "It lets me be faster and looser when I'm playing for keeps."
                
                "I guess that makes sense," they say, in a tone suggesting they're unconvinced.
                
                Dammit. Not ideal.
                *goto covera
            *else
                Mal nods thoughtfully. "That never worked for me, but I know some folks swear by it."
                
                "Some folks?" you ask, because $!{cg} also taught you that diverting conversations is a good way to maintain your story.
                
                "Me, for example," says Dion. "My power acts unpredictably if I don't concentrate."
                
                "Oh is 'unpredictable' what you're going with now?" Mal raises an eyebrow.
                
                Dion clears his throat, looking away awkwardly. "No comment."
                *goto coverb
            
*label covera
*page_break
That could have gone better. Mallory is clearly sharper than they'd have you believe from their playful demeanour.

*goto continue

*label coverb
*page_break
You don't think they suspected anything, although you're in two minds as to whether Mallory was testing you on purpose. Clearly, they're sharper than they let on.

*label continue
You'll have to watch yourself around them.

"Anything else?" you ask, because it's better to take initiative.

Dion shakes his head. "No." The beep of a text message sketches a frown across his face. "Excuse me a second," he says, pulling a phone from his pocket as he exits the room.

You're left with Mallory's full attention. The silence barely lasts three seconds.

"So, who's your favourite Glory Hound?"

That is… not a question for which you have a coached answer. You were always going to run out of carefully curated replies at some stage; it's impossible to prepare for every last topic, and at a point it starts doing more harm than good.

Yeah, you knew that a conversation would escape the rails sooner or later. You just didn't expect Mallory to annihilate the tracks with a stick of dynamite.

*if observation >= 39
    Their expression is difficult to read, but you think you see the shade of a smile on their lips.
    
    They're… [i]probably[/i] messing with you.
    *choice
        #Challenge them on it.
            *set rel_wyrd +2
            "Are you hazing me?" you ask, folding your arms.
            
            "Aww, hazing is such a loaded word," Mal replies. Then the smile blooms into full life. "But absolutely, yes."
            *goto mal
        #Just say the first Hound who comes to mind.
            *set rel_wyrd +2
            "Arcade."
            
            *if (arcade_nose)
                "Is that why you smashed his face in?" Mal asks, raising an eyebrow.
                
                "Yeah it's how I show affection."
                
                "Hah!" Mal grins. "Nice. Knew you'd have a fun answer."
                
            *else
                "Yeah?" They rub their chin speculatively. "I can see it."
                
                "You think?"
                
                The smile slowly comes out into the open. "Nah, I'm making this up as I go."
                
            *goto mal
    
*else
    Their expression gives nothing away. Is this a trap?
*choice
    #"Favourite... how?" I need a better idea of what they're asking.
        "You've never heard of villains picking out a favoured enemy?" Mal shakes their head. "I'm a little sad for you."
        
        "Right, but favourite to fight? Banter with? That's pretty broad."
        
        Mal laughs suddenly. "Okay, I don't even need to know your actual answer, that's perfect."
        
        You frown, beginning to suspect you're on the wrong side of a joke. "What's perfect?"
        
        "I wanted to see how you'd react to the question, and you asked me to be more specific. That's amazing."
        *goto mal
    #"Why would I have a favourite hero?" The best defence is a good offence.
        "Every villain needs a good nemesis," Mal replies. "It's a classic."
        
        "That doesn't make them a favourite. It's the opposite if anything."
        
        "What's hate but another side of—" they break off and grin. "Honestly, yeah. I don't want to fake argue. I just wanted to see how you'd react."
        *goto mal
    #"I don't understand." If in doubt, feign ignorance.
        They start to say something, stop, and then laugh, shaking their head. "I was going to try and keep you going, but I'm drawing a blank."
        
        You frown. "Meaning?"
        
        Mal shrugs. "Honestly, I was just trying to provoke a reaction."
        *goto mal
    
    
*label mal

So they were poking at you for the sake of quick kicks. Cool.
*page_break
Mallory's good humour abruptly fades. "Ah, dammit. Sorry."

*if expressive > 60
    "You should be," you quip. They breathe a limp laugh.
    
*elseif expressive < 40
    You lift an eyebrow and wait for them to continue.
    
*else
    "What for?"
    
"I shouldn't mess with you. It's just good to have somebody who isn't Dion around."

As best as you can tell, they seem genuinely contrite.
*choice
    #"No harm done."
        *set rel_wyrd +2
        "Yeah, but still…" They trail off, and then shrug. "Gracious of you, though."
        
    #"Thanks for apologising."
        They nod. "You're welcome."
        
    #"Knock it off, then."
        *set rel_wyrd -2
        "Sorry, I don't make promises I can't keep," they fire back instantly, but then raise both hands. "I'll ease up though."
        
        Ugh. Great.
        
The conversation tapped out, you both settle in to wait. Initially, you occupy yourself with inspecting the apartment further, though it swiftly becomes clear that your first impression is going to be the only impression necessary. As the delay begins to stretch past five minutes, your attention wanders.
*page_break Movement.

It's in the corner of your eye. You glance back across the room and catch Mal looking you up and down. Their mouth quirks into a smile. They raise a hand, index finger extended.

"Disclaimer: not already messing with you again." They lower the hand, giving a couple of tiny bobs of their head. "Gotta say, I definitely prefer you when you're not covered in black goop, $!{aka}."

*if expressive > 60
    There's a teasing lilt in their voice that you haven't heard before—wait are they flirting with you!?
*elseif expressive > 50
    There's a teasing lilt in their voice that you haven't heard before—hold on.
    
    You think they might be flirting with you.
*else
    There's a teasing lilt in their voice that you haven't heard before—oh. Wait.
    
    Ah.
    
    They're flirting with you.
*if ((pastcrush = 1) and (not (compatible_beth)))
    *goto regularflirtmal
    
*elseif ((dating) or (pastcrush < 5))
    A lump settles in your throat.
    
    You don't think even the faintest notion of intimacy has passed through your head since… since back then.
    *choice
        #Those wounds are still raw. @{ftone [Future romance will be more difficult, but not impossible]|}
            @{dating Thorns constrict your chest, squeezing until you can barely breathe.|Even though you were mostly nursing a crush, that doesn't change how you felt. That doesn't lessen the pain.}
            
            *if ((dated_beth) or (pastcrush =1))
                *set brokenheart 1
                *if (origin = 1)
                    *goto howareyou
                
                *elseif (origin = 2)
                    *label lastyousawbeth
                    The last you saw of Beth was on the far side of an escape that you couldn't reach. Her leaving you behind.
                    
                    *goto beththoughts
                
                *elseif (origin = 3)
                    *if (ranaway)
                        *goto howareyou
                    *else
                        *goto thoughtyoumade
                *elseif ((origin > 3) and (origin < 6))
                    *goto thoughtyoumade
                
                *elseif origin = 6
                    *goto lastyousawbeth
            *elseif ((dated_prii) or (pastcrush =2))
                *set brokenheart 2
                *if (origin = 1)
                    *label ranawaypriishauna
                    *if (ranaway)
                        *if (guilt =1)
                            Thinking about @{(prev_li = "Prii") Prii|Shauna} only stokes your guilt further, gnawing away at your heart and leaving nothing but remorse in its wake.
                            
                        *elseif (guilt = 2)
                            *goto shapedhole
                            
                        *else
                            Your emotions make a joke of your desperate claims that you [i]tried[/i] to do the right thing, you [i]tried[/i] to return for the others. You weren't there for  @{(prev_li = "Prii")  Prii, nor Shauna,|Shauna, nor Prii}, and the pain of that knowledge eats away at you every day.
                  
                        If you weren't such a coward, maybe @{(prev_li = "Prii") they—maybe they'd still…|she—maybe she'd still…}
                        *goto malpause
                    
                *elseif (origin =2)
                    *label leftbehindpriishauna
                    You thought you made the right choice by sticking with Beth and Grant.
                     
                    Knowing then what you know now. Knowing that the next time you saw @{(prev_li = "Prii") Prii, they'd—they would… they'd be… gone,|Shauna, she'd—she would… she'd be… gone,}  you're not sure your decision would stay the same. 
                    
                    *goto malpause
                
                *elseif (origin = 3)
                    *if (ranaway)
                        *goto ranawaypriishauna
                    
                    *else
                        *goto rightinfrontprii
                        
                *elseif ((origin > 3) and (origin < 6))
                    *label rightinfrontprii
                    Prii died @{lasthelp right in front of you|in your arms|right in front of you}. How can you possibly get over that?
                    
                    *if (pastcrush = 2)
                        @{confession You managed to tell them your feelings at the last second, but it barely counts as closure.|You never even told them your feelings for them.}
                        
                    There's a Prii-shaped hole in your heart. Their charm. Their humour. Their smile. Patching it up seems impossible.
                    
                    *goto malpause
                
                *elseif (origin = 6)
                    Prii told you to help Shauna instead of them.
                    
                    It's hard to tell yourself that matters, and harder still to believe it. Not when the last sight you had of them was laying on the ground dismembered.
                    
                    And even then, they were looking out for others. Looking out for you.
                    
                    *if (dating)
                        How could anyone ever compare to Prii? How could anyone ever patch the hole they left in your heart?
                        *goto malpause
                        
                    *else
                        How could you ever feel the way you felt about them for someone else?
                        
                        @{confession Why didn't you tell them sooner?|You never even told Prii you loved them.}
                        *goto malpause
                
            *elseif ((dated_shauna) or (pastcrush =3))
                *set brokenheart 3
                *if origin = 1
                    *goto ranawaypriishauna
                
                *elseif (origin = 2)
                    *goto leftbehindpriishauna
                
                *elseif (origin = 3)
                    *if (ranaway)
                        *goto ranawaypriishauna
                    
                    *else
                        *goto shaunarightinfront
                    
                *elseif ((origin > 3) and (origin < 6))
                    *label shaunarightinfront
                    Shauna died @{lasthelp in your arms|right in front of you|right in front of you}. How can you possibly get over that?
                    
                    *if (pastcrush = 3)
                        @{confession You managed to tell her your feelings at the last second, but it barely counts as closure. She even got there first, one last time.|You never even told her about your feelings for her.}
                        
                    There's a Shauna-shaped hole in your heart. Her earnest kindness. Her creativity. Her smile. Patching it up seems impossible.
                    *goto malpause
                
                *elseif (origin = 6)
                    The last you saw of your @{dating girlfriend|crush}, she was bleeding to death and unconscious, vanishing on the far side of an impassable barrier. Of course you're not over her.
              
                    
                    *if pastcrush = 3
                        *label confessdenied
                        You never even told @{(prev_li = "Shauna") her|him} your feelings for @{(prev_li = "Shauna") her|him}.
                        
                    *goto malpause                
            *else
                *set brokenheart 4
                *if ((origin = 1) or (ranaway))
                    *goto howareyou
                
                *elseif (origin =2)
                     The last you saw of your @{dating boyfriend|crush}, he was bleeding to death and unconscious, vanishing on the far side of an impassable barrier. Of course you're not over him.
                     
                     *if pastcrush = 4
                         *goto confessdenied
                     
                     *goto malpause
            
                *elseif ((origin > 2) and (origin < 6))
                    *label thoughtyoumade
                    
                    How are you supposed to have closure when you don't even know what happened to your @{dating romantic partner?|crush?}
                    
                    You thought you made the right choice by staying with Prii and Shauna.
                     
                    Knowing then what you know now, that you'd be left in the dark about @{(prev_li = "Grant") Grant|Beth}, you're not sure your decision would stay the same.
                    
                    *goto malpause
                    
                *elseif (origin =6)
                    Grant died, and @{dating you weren't even there with him when it happened|you never even got to tell him how you felt}. He [i]saved your life[/i], and that cost him his own.
                    
                    *goto malpause
            
        #I wouldn't know where to start nowadays.
            Even if you could set aside what happened—and that's a load bearing 'if' bearing a record-breaking load—you're not sure you remember how this works. You're barely re-learning conversation, let alone flirtation.
            
            You can't—won't—just forget ${prev_li}. But… maybe you can make a little room in your heart again. Maybe.
            *goto malpause
        #It's been a long time. Long enough?
            Your heart bears all kinds of wounds. Some of it is scar tissue, some continue to bleed even now.
            
            Truthfully, you don't know whether you'll ever get over ${prev_li}. But maybe there's space for someone else. Maybe.
            *goto malpause

*else
    *label regularflirtmal
    *choice
        *if ((ace) and (aro = 2)) #Well, this is awkward.
            You regard them silently for a moment, not really interested in both dissecting whether that was actually a flirt and getting into a whole thing about your sexuality.
        
            Fortunately, something in your response seems to clue Mallory in that their advance is unwanted, and they swap gears. "Not that there's anything wrong with your goop. You could take that on the runway."
        
            *label therunway
            *if expressive >= 60
                Much better territory. You relax a little. "Oh, yeah. I can see it in the fall collection already. Fetching designer membrane. Get it now while it's the hot new item."
            
                Mal smirks.
            
            *elseif expressive <= 40
                "It's not goop, it's a membrane."
            
                Mal nods thoughtfully. "That makes sense. I was wondering."
            
            *else
                An easier topic. "Not so sure the fashionistas would be into a look like mine."
            
                Mal smirks. "You'd be surprised. I've seen some shit on those shows."
            
            *goto dionback
        #How forward.
            "You sure don't waste time," you say, a note of challenge in your voice.
        
            Mal laughs. "Hey I call it how I see it."
        
            "Uh huh."
        
            *goto dionback
        *selectable_if (aro !=4) #They're kind of cute. I'm not complaining. @{ftone [Flirt, passive]|}
            *set flirt_wyrd +1
            *set interest_wyrd true
            "Nice of you to say so," you reply, a slight smile edging onto your face. Getting too close to anyone is definitely a bad idea, but nothing wrong with having a bit of fun, right?
        
            Mal winks, erasing any residual doubt that they're flirting.
        
            *goto dionback
        #I mutter something noncommittal, unsure what to say.
            Your mumbling response seems to key Mallory in that you're not quite comfortable, and they swap gears. "Not that there's anything wrong with your goop. You could take that on the runway."
            *goto therunway
        *selectable_if (aro != 4) #I'm flustered by the attention and don't know how to respond. @{ftone [Flirt, passive]|}
            *set flirt_wyrd +1
            *set interest_wyrd true
            "I… thanks?" you say, stumbling on your words.
        
            Mal grins. "Anytime."
        
            Oh. Lucky you?
        
            Unable to meet their eye while they're smirking like that, you avert your gaze.
        
            Mercifully, Dion striding back into the room spares you any more of this conversation. "Sorry about that," he announces.
        
            *goto dionback2
        #I brush them off.
            "If you say so," you reply.
        
            Mal doesn't appear particularly perturbed at being rebuffed. "Oh don't get me wrong, the goop is great, just not very expressive, you know?"
        
            *goto dionback
    
*label beththoughts

@{battitude In some ways, understanding Beth's decision makes it hurt all the more. There's no closure.|Resentment simply makes the pain fester. She meant so much to you. Not so the reverse.|You're so often numb to what Beth did. And with your heart frozen over, how is it to heal?|Just thinking about it is enough to reopen the same old wounds. The last person you opened your heart to ended up tearing it in half.|Sure, just thinking of Beth is enough to make you angry, but isn't that the kicker of it all? It's the ones you care about who can hurt you the most. The harshest wounds come from inside.} 
*goto malpause

*label howareyou
How are you supposed to have closure when you don't even know what happened to your @{dating romantic partner?|crush?}

*if (ranaway)
    *if (guilt =1)
        Thinking about @{dated_beth Beth|}@{dated_prii Prii|}@{dated_shauna Shauna|}@{dated_grant Grant|}@{pastcrush Beth|Prii|Shauna|Grant|} just stokes your guilt about what you did even further. It gnaws away at your heart, leaving only remorse in its wake.
        *goto malpause
    *elseif (guilt = 2)
        *label shapedhole
        Remembering what you did, how you left the others behind, it gets harder and harder to hold to your resolve. Was running really the right decision when it left a gaping @{dated_beth Beth-shaped|}@{dated_prii Prii-shaped|}@{dated_shauna Shauna-shaped|}@{dated_grant Grant-shaped|}@{pastcrush Beth-shaped|Prii-shaped|Shauna-shaped|Grant-shaped|} hole in your heart?
        
        *if ((prev_li = "Prii") or (prev_li = "Shauna"))
            When you know what fate your cowardice sealed for @{(prev_li = "Prii") them|her}?

        *goto malpause

    *else
        Your emotions make a joke of your desperate claims that you [i]tried[/i] to do the right thing, you [i]tried[/i] to return for the others. It's your own fault that @{dated_beth Beth's|}@{dated_prii Prii's|}@{dated_shauna Shauna's|}@{dated_grant Grant's|}@{pastcrush Beth's|Prii's|Shauna's|Grant's|} fate is a mystery, and the pain of not knowing eats away at you, day after day.
        *goto malpause   

*label malpause
*page_break
Your embattled emotions clearly show on your face, because Mallory backs all the way off. "Not that there's anything wrong with your goop," they hastily add.

Snarled within a tangled knot of loss and longing, the only response you can muster is a nod.

Mercifully, the return of Dion makes for a timely distraction. "Sorry about that," he says, striding back into the room.

*goto dionback2

*label dionback
Before the conversation can go any further, Dion strides back into the room. "Sorry about that."

*label dionback2
Mallory doesn't miss a beat. "You're always on your phone, man. When did we drift apart like this?"

"I wouldn't complain if we drifted further," Dion ripostes, and Mal laughs.

"Everything okay?" you ask Dion, casually probing.

He nods. "Yes, but a response couldn't wait." He moves back across to the counter and grabs the briefcase. "Speaking of which, we should leave. They're expecting us."

Seems the message will remain an unanswered question for now. Nothing else to do but head out.
*page_break Depart.

It's an odd experience to be sharing the sidewalk with Dion and Mallory again. Yesterday, you were in full costume, flush with exertion and hustling to escape the scene of the crime. Now you look no different from any other trio of friends out for an afternoon stroll. Dion sets the pace, striding purposefully, eyes forward. Mal is more casual, a little spring in their step. Occasionally they swing their arms, and now and then clap their hands in front or behind them, completely at ease. You end up somewhere in the middle of them, lost in thought.

The root of the strangeness isn't entirely the contrast from last time. You're with company. In public. You could strike up a conversation with either of them. About anything you wanted. And there would be no reprimand. Nobody snapping at you to speak only when asked.

How are you feeling?
*choice
    #Bitter. It shouldn't be so novel.
        *set seethe +2
        *set walkfeel 1
        This is so normal and pedestrian. The type of experience a regular person could have every day of their life and wouldn't even think about. Yet for you, it's not only a rarity, it's inauthentic. There's an agenda. A mission.
        
        Caveats. On walking around with people you know. It's one big joke, and you're the punchline.
    #Melancholy. It's not real.
        *set break +2
        *set walkfeel 2
        This is a forgery. You're admiring the brushwork of a fake painting.
        
        Nice to look at. Nice to imagine for a little while that you're a regular person with regular friendships. 
        
        But ultimately? Ultimately it's worthless.
        
        Regular people don't have missions and assignments. Regular people don't have cover stories.
    #Nostalgic. I'm reminded of how things were.
        *set seethe +1
        *set loyal +2
        *set walkfeel 3
        You used to walk around town accompanied by at least one friend near enough every day.
        
        A sliver of that old feeling. Something to cherish while it lasts. 
        
        It's not the same. Of course it's not. Just… sometimes it's nice to wander through memories of happier times, if only for a little while.
    #I feel nothing at all.
        *set loyal +1
        *set break +1
        *set walkfeel 4
        Opening yourself up leaves you vulnerable. Distracted.
        
        You have too many wounds and the stakes are too high to afford distractions. Feelings are already such a huge complication without you delving deep into every new pocket you come across.
        
        *if speciality = 3
            Armour your emotions like you armour your flesh, and carry on.
            
        *else
            Keep yourself cold to them. Avoid the temptation. Carry on.
            
*page_break

After a couple of blocks, you arrive at a small apartment building. There's an old buzzer system at the entrance, every last label peeling, crossed off, or missing entirely. Dion ignores it in favour of walking straight through the unlocked door.

"Third floor, apartment 303." he says to you and Mal, and then heads for the stairs. You're not stunned to find there's no elevator, though you don't think you would have trusted one anyway. Everything here reeks of neglect. Worn, stained carpets. Yellowing wallpaper. Blown lightbulbs. The scent of stale smoke. You follow Dion into the stairwell and start climbing.

*if guts < 20
    Your calves and thighs burn as you reach the third floor, and you have to stop to catch your breath. Urgh, @{workedout just goes to show why you need to get your fitness up. Hopefully working out earlier will pay off if you stick with it.|you're really not in great shape. Might need to work on that.}
    
*else
    The stairs aren't too bad, and your breathing is only a little heavier by the time you reach the third floor. @{workedout Maybe those morning workouts are paying off after all.|}
    
    
Mal, who ascended ahead of you and almost seemed to bounce their way up the steps, is waiting just inside the hallway, casually propping the door open with one foot. They cast out a hand dramatically, gesturing you to go in ahead of them, and you oblige.

Together you join Dion in clustering outside apartment 303. Dion raps at the door. There's a muffled shout of acknowledgement from within. A few seconds later the door opens, though only a couple of inches. An icy blue eye appears in the narrow gap, and then alights on Dion.

"Oh hey. Come on in." With the sound of a rattling chain, the door opens fully, affording you a proper look at the figure waiting beyond, a tall and rangy…
*fake_choice
    #Man.
        *set wname "Wilson"
        *set wgender "male"
        *set whe "he"
        *set whim "him"
        *set whis "his"
        *set wboy "boy"
        *set wman "man"
        *set wboyfriend "boyfriend"
    #Woman.
        *set wname "Wilma"
        *set wgender "female"
        *set whe "she"
        *set whim "her"
        *set whis "her"
        *set wboy "girl"
        *set wman "woman"
        *set wboyfriend "girlfriend"
    #Person.
        *set wname "Willow"
        *set wgender "nonbinary"
        *set whe "xe"
        *set whim "xem"
        *set whis "xer"
        *set wboy "kid"
        *set wman "person"
        *set wboyfriend "datefriend"
        *set wilqueer true

"Wait, you're new." The door${wman} immediately moves to bar your path, expression flat and suspicious. "Dion? We good?" Those pale eyes remain locked on you even as their owner addresses your companion.

"We're good, $!{wname}," Dion confirms. "$!{mc_he}@{mc_singular 's|'re} with us." 

$!{wname}'s posture and face instantly relax. "Of course. That's great." $!{wname} gives you a nod. "Sorry, can't get careless. Like you just heard, I'm $!{wname}. $!{whe}/${whim}." $!{whe} gestures to ${whim}self. "Call me Wil if you like."

"$!{aka}," you reply. $!{whe} nods, and then steps back out of the doorway, motioning for the three of you to come in. The entrance leads directly into a small porch area with a door on all three of the other walls.

"Thanks, $!{wname}," says Dion, walking inside. "Are the others here?" he asks as Mallory follows, exchanging a friendly fistbump—which doesn't quite touch—with Wil on their way past.

"Sure are," Wil answers. "Go right ahead." $!{whe} hangs back while Dion and Mal venture deeper into the apartment, and then turns back to you with a long, appraising look. @{mc_height DUMMY|$!{whe} towers over you, looming without really trying.|$!{whe} is much taller than you, almost looming.|$!{whe}'s taller than you, enough for the difference to be noticeable.|$!{whis} height is very similar to your own; you imagine Wil would be pretty intimidating if you were shorter.|With your commanding height, you're probably one of the few people ${whe} has to look up to.} $!{whis} mouth is pressed in a thin line, ${whis} black lipstick cutting a stark contrast to ${whis} ghostly pale skin and short, ash blonde hair. Black's a theme of ${whis} outfit, all dark and distressed, broken up by the occasional flash of skin or silvery stud.

The scrutiny is getting a little intense.
*fake_choice
    #"Can I... help you?"
        *set loyal +1
        Unexpectedly, ${whis} lips twitch into a wry smile. "Sorry, just building up to something."
        
        You have no idea what ${whe} means.
    #"We should probably follow them."
        *set loyal +1
        "Just a second," says Wil. "Your friends already know the score, but there's something you need to hear."
        
        "What do you mean?"
    #"Are you trying to intimidate me?"
        *set seethe +1
        Wil's eyebrows rise. "Hah, uh, no. But it might come across that way."
        
        You scrutinise ${whim}, trying to grasp ${whis} meaning.
    #Meet ${whis} eyes and stare ${whim} down.
        *if guts > 22
            *set seethe +1
            You're not going to be intimidated. You try to match ${whis} intensity with your own. @{feature |Your eyes are just as cold as Wil's.||} $!{whe} doesn't frighten you, and you hold ${whis} gaze until ${whe} starts to speak.
        *else
            *set break +1
            You try to match ${whis} intensity with your own, but that's easier said than done. There's a chill in those eyes. After a couple of seconds you falter and break eye contact.
    #I break eye contact and look away.
        *set break +1
        Feeling uncomfortable, you glance off to the side, hoping that ${whe}'ll get the hint and stop eyeballing you.
        
        ${whe} does not.


Wil sighs. "I don't like doing this. Feels like a terrible way start things off with someone new. Especially a possible teammate." Wil shrugs. "It's important though, so…" ${whe} flips a thumb over ${whis} shoulder. "This isn't a hideout or a safehouse. My roomies and I actually live here, and neither of them get to check their powers at the door. You understand? This is what we've got. Dion I trust to a point. You, $!{aka}, I don't know a thing about." Wil flexes the fingers of one hand, fanning out every slender digit. The tendons stand out against their almost translucent skin. "Respect this space. Don't bring mask business or trouble to the door. Follow those rules and we'll get along just fine."

How do you respond?

*choice
    #I agree that I wouldn't like my home messed with either. 
        *set rel_wil +2
        *set wimpression 1
        Your space is barely either a space or actually yours, and you still understand the point that ${whe}'s making.
        
        "Hey, I get it," you say. "This is your home. You want to keep it separated from mask business."
        
        Wil nods gratefully. "Exactly."
        *goto movinginside
    #I don't appreciate ${whis} tone, and call ${whim} out for it.
        *set instinctive %+ 5
        *set wimpression 2
        Why is ${whe} acting like you're trailing half the Glory Hounds in behind you? This is ridiculous.
        
        *if expressive > 45
            "We literally just met and you're jumping down my throat. Can you chill?"
            
        *else
            You fold your arms. "Not if you keep throwing demands around, we won't."
            
        Wil frowns. "Look, I'm just making sure you know what's what, $!{aka}. I'm not trying to pick a fight. The opposite, actually."
        *choice
            #"Could have fooled me."
                *set seethe +1
                *set rel_wil -2
                Yeah, no. You're not putting up with ${whis} nonsense.
                
                Wil narrows ${whis} eyes, but in lieu of escalating further, shrugs ${whis} shoulders. "I've said my piece. You can take it however you want, $!{aka}."
            #"Fine. Message received."
                *set loyal +1
                You're still not thrilled, but at least you got your point across.
                
                Wil relaxes marginally.
                
        *goto movinginside
    #I nod: I don't care enough to make a big deal out of this.
        *set loyal +1
        *set rel_wil +2
        *set wimpression 3
        It's kind of whatever at the end of the day. Wil's setting a boundary, and even if you don't see why ${whe}'s so insistent, it doesn't cost you anything to go with the flow. You give ${whim} a nod.
        
        *label nodnod
        At your gesture, Wil relaxes marginally. "Thanks. Really."
        
        "Sure."
        *goto movinginside
    #I nod: I don't want a confrontation.
        *choice
            #...Because this is stupid.
                *set wimpression 4
                *set seethe +1
                *set instinctive %- 5
                *set rel_wil +2
                Wil giving you the third degree within a couple of minutes of meeting you is certainly a choice ${whe}'s making. Still, just because ${whe}'s being ridiculous doesn't mean you have to be too. You give ${whim} a nod.
        
            #...Because I don't like arguments.
                *set break +1
                *set instinctive %- 5
                *set rel_wil +2
                Wil giving you the third degree so soon after meeting you is making you nervous. You really don't want to get into a fight, for a whole host of reasons. Hoping to pacify ${whim}, you give ${whim} an awkward nod.
        *goto nodnod
    #I point out that meeting here is literally bringing mask business to the door.
        "If you're so serious about security, then why aren't we meeting somewhere else?" Seems to you that this conversation-slash-confrontation could have easily been avoided by setting up in a neutral location.
        
        Wil frowns. "It's not totally up to me. Like I said, my roomies have the kinds of powers that don't come with an off switch. It'd have been real conspicuous."
        *choice
            #I acknowledge that ${whis} point makes some level of sense.
                *set wimpression 1
                The others didn't tell you much about the group you're meeting, but you can understand wanting to keep some level of privacy.
                
                "I guess you wouldn't want to walk around in a big group right as you're discussing going villain."
                
                Wil nods gratefully. "Exactly. Thanks for understanding."
            #No. Architect, Wyrd, and I met up in a perfectly good abandoned building yesterday.
                *set wimpression 2
                Perfectly good at being abandoned at least.
                
                You shake your head. "If you guys go villain and have very visible powers, then it's going to be difficult to keep things separate. Using safehouses and meeting spots is smarter."
                
                Wil sighs. "That's your opinion. But I've said my piece and I'm not here to argue. I'd appreciate if you keep the ask in mind."

*label movinginside
*page_break

Wil mimes closing a book with ${whis} hands and then forcibly brightens ${whis} voice. "Anyway. That's over and done with, so let me show you inside." $!{whe} turns and heads for the door Dion and Mal went through.

You follow Wil into the next room. @{livingconditions You hardly have room to talk when it comes to crummy living arrangements, but the cramped, damp-ridden apartment that meets your gaze isn't exactly in amazing repair.||Your own living arrangements are lacking to say the least, but the cramped, damp-ridden apartment awaiting you isn't much better.| It says something that your own state-of-the-art abode loses out only narrowly to the cramped. damp-ridden apartment that awaits. You're not quite sure which accommodations the comparison flatters less.} Mallory lounges against the one section of wall not rendered inaccessible by haphazard piles of belongings, while Dion stands primly amidst the chaos, holding the briefcase secure in both hands. Two unfamiliar figures rise to their feet, turning in your direction as you enter; a stocky young woman with a farmer's tan and a shorter, slimmer man of a similar age, his body studded with strange protrusions.

The latter fixes you with a glare, naked suspicion in his glittering green eyes. "Who the hell is that?"
*fake_choice
    #I wait to be introduced.
        *set break +1
        *set rel_wil +1
        You aren't waiting for long. Dion speaks. "$!{aka} is the other new recruit I mentioned. I vouch for ${mc_him}."
        
    #I snap back aggressively.
        *set seethe +1
        *set rel_wil -3
        *set antagonise true
        "You people treat all your guests like this?" You find your hands bunching into fists. First Wil, now this guy. You're getting real tired of the hostility.
        
        "Whoa, whoa, easy!" Wil neatly steps in front of you. "This is $!{aka}, ${mc_he}@{mc_singular 's|re} with Dion and Mallory." $!{whe} shoots an aggrieved look back over ${whis} shoulder. @{wimpression You didn't exactly hold up your end of the deal just now.|You tip your chin back in defiance. You already told ${whim} what you thought of ${whis} nonsense.|That's ${whis} problem; you didn't agree to just stand here and take it.|That's ${whis} problem; your tolerance for stupid only goes so far.} 
        
    #I politely introduce myself.
        *set loyal +1
        *set rel_wil +2
        "$!{aka2}. I'm with these two." You keep your tone neutral and calm. Hopefully this doesn't get ugly. Wil shoots you a very brief but very appreciative look.
        
*set met_ktg true
"Hmph." The stranger doesn't sit down, rolling a misshapen shoulder. A massive horn of bone resembling the ornamental pauldron of some evil knight has pushed through the skin. It's all bone, you realise, from the harsh ridge over one eyebrow to the razorlike spurs running the length of his right arm. He notices your scrutiny, and his scowl only deepens.

Wil takes it upon ${whim}self to continue the introductions. "This is Teddie and over there is Kay." $!{whe} gestures to the girl, who gives an awkward wave.

"Hi. Sorry about the mess. Maid hasn't been in yet." Her voice is husky and quiet, like she's worried about her own volume. Still, she smiles at her joke, and it reaches her eyes. Amber. Horizontal pupils. A pair of horns curl backward behind her ears, parting fluffy, grey-white hair.
*fake_choice
    #"I was expecting room service."
        *set rel_kay +2
        Kay giggles softly, then looks self-conscious about it. She looks away, putting the back of one hand to her mouth.
        
    #"Don't worry about it."
        *set rel_kay +2
        Kay's smile widens slightly.
        
    #I shrug.
        *set expressive %- 5
        Doesn't really make any difference. Not like it's a house party.

Completely ignoring the exchange, Teddie turns to Dion. "$!{mc_he}@{mc_singular 's|'re} here. Show us the papers."

"Of course." Dion hands Teddie the briefcase, who takes it warily before returning to his spot on the couch. The coffee table in front of him is too piled with junk to work as a surface, so he opens the case on his knees, hunching forward protectively. Kay takes a seat next to him, and Wil leans ${whis} lanky frame over the backrest to look past Teddie's shoulder.

A few minutes pass as the three of them sift through the contents of the briefcase. Wil and Kay occasionally reach out a hand to point to one paragraph or another, while Teddie simply reads, expression unchanging from a furrowed, half-spined brow.

Eventually, Teddie straightens, calling across to Dion. "You got everything." A reluctant admission.

Dion sketches a bow. "Delivered as promised."

Teddie nods. He's still scowling.
*choice
    #"We held up our end of the deal. Time for yours." Stick to business.
        *set rel_wyrd -3
        *set rel_architect +2
        *if (incharge)
            Mallory laughs. "You really are coming for Dion's job, $!{aka}."
            
        *else
            Mallory laughs. "Careful, Dion, ${mc_he}@{mc_singular 's|'re} coming for your job."
            
        Dion ignores them, instead keeping his attention on Teddie. "$!{aka2} is right. You've had a few days to think this over, so I'd appreciate an answer now rather than later."
    #"Disappointed?" I take a jab.
        *set seethe +1
        *set rel_teddie -2
        *set rel_wyrd +2
        *set rel_wil -2
        *set antagonise true
        Teddie glowers at you. "No," he snaps.
        
        "It's just a lot of info to digest," says Wil. "Really scummy info at that."
        
        "Leeches," says Dion, with emphasis. "In any case, you've had a few days to think this over, so I'd appreciate an answer now rather than later."
             
    #I keep myself to myself. I want to see how this plays out.
        *set expressive %- 3
        Jumping straight in is unnecessary. A subtle negotiation is happening in front of you, and you'd rather see how the scales balance than try to tip them yourself.
        
        *label given
        Dion continues. "Given you've had a few days to think this over, I'd appreciate an answer now rather than later."
        
    #It's not my place to comment. This is Dion's show.
        *set loyal +1
        You're the junior partner in this new team. It probably won't go down well if you start throwing your weight around. Head down and mouth shut.
        
        *goto given


Moment of truth. Will they join up?

Wil pushes ${whim}self up by the arms on the back of the sofa, craning ${whis} neck over ${whis} friends. "What are we thinking, kids?"

"Don't call us kids. Dick," Teddie growls, which strikes you as a reflex.

He and Kay exchange long looks, silently communicating. At length, Kay nods slightly.

That's apparently enough for Teddie. "We're in," he says.

Wil spreads ${whis} hands. "In that case, me too."

Dion smiles. "Glad to have you aboard." He draws himself up and addresses the whole room. "And on that note, I think we've discussed quite enough business in your lounge. Plus, Mallory and I have a few errands to run. Let's exchange numbers and then we'll give you folks some peace. Tomorrow, you can all see our real base."

*choice
    #"Is that the condemned building or the one chair apartment?"
        Dion breathes a short 'ha'. "Neither. You'll see."
        
        How many hideouts can a villain possibly have?
        
        …Actually, that's not even a rhetorical question. Three safehouses in one town? You file the thought away for later investigation.
        
    #"What kind of errands?"
        "Necessary ones," Dion replies evasively.
        
        Hm. Seems like you're not fully in the loop yet. You've still got digging to do.
        
    #Sounds good to me.
        *if mc_health > 1
            The more time you get to heal up the better in your books.
            
        *else
            You don't have a strong opinion.
            
        Besides, the longer everyone knows you, the more trust you'll gain. You're just getting started.


"Giving my number to three people at once?" Mal shakes their head, wearing a smirk that has already grown familiar. "You'll make me blush, Dion."

"You're shameless and don't even try to pretend otherwise."

Mal's jaw hangs open for a second, and then they shrug. "Welp. Don't think there's any coming back from that one. It was a good run." They stroll across the room and begin trading contact information with the others.

Meanwhile, Dion addresses you. "$!{aka2}, you should leave separately. We moved around together earlier and there's no harm in being careful."
*choice
    #That makes sense.
        *set instinctive %- 5
        You've already had a couple of clandestine meetings today. Even if it's unlikely that anyone's suspicious of you right now, the easiest way to divert attention is to avoid attracting it in the first place. Hanging tight for an extra few minutes is an easy concession for extra security. You nod.
        
    #That seems a bit much...
        *set instinctive %+ 5
        Both you and Dion had your faces fully covered yesterday, and your power vastly changes your look. @{speciality |Vastly, [i]vastly[/i] changes your look. |[i]Vastly[/i] changes your look. |DUMMY} Splitting up seems unnecessary. Most heroes rarely go for unmasked villains in public anyway; that treatment is reserved for mass murderers and block levellers.
        
        Still, it's probably not worth arguing the point. Hanging tight for a few minutes is no big deal. You nod.
        
    *if (interest_wyrd) #I'm caught up on that exchange just now. Was Mallory not actually showing interest earlier? @{ftone [Flirt, passive]|}
        *set flirt_wyrd +1
        Maybe they're just the flirtatious type. @{aro |You're not sure what you feel about that, but there are definitely shades of disappointment.|If so then well, hey, that doesn't [i]not[/i] work for you. Flirting can be fun by itself. If you can even remember how that works nowadays.|}
        
        Distracted, you give Dion an absent nod.

"Excellent. Let me take your number and I'll text you the details shortly."

Conveniently, by the time you've supplied your digits to Dion, Mal is finished up with the trio and returning to his side.

"Ready to rock?" Mal asks. Dion simply nods. Mal heads for the exit, turning around before they leave to give a double-handed wave to the whole room. "Later! Look after $!{aka}. $!{mc_he} @{mc_singular isn't|aren't} allowed snacks after three PM!" With that, they back through the door. Dion follows with a much more straightforward 'goodbye'.

You're left alone with three near-strangers, and all of their eyes immediately fall on you.
*choice
    #Thanks, I hate it.
        *set loyal +1
        It's difficult not to shrink and cower under the scrutiny. In your experience, commanding the room's attention is very, very bad.
        
    #I won't be intimidated.
        *set seethe +1
        You can handle a room of people. @{wimpression |You already showed Wil that you aren't going to tolerate ${whis} BS.||}
        
        Folding your arms, you wait for one of them to make the first move.
        
    #Instinctively I feel like I've done something wrong.
        *set break +1
        An apology readies itself to jump off your tongue, but you hold it back. There's no reason for you to offer one.
        
        Except the false pretences. Can't forget those. 


Luckily, Wil breaks the tension that perhaps only you were feeling. "I suppose this gives us time to swap numbers, $!{aka}."  $!{whe} raises ${whis} phone. "If you give me yours, I can pass it to these guys too."

While that makes sense, it occurs to you that both Teddie and Kay could easily do the same, if you feel like indulging in a tiny amount of boat-rocking.
*choice
    #Wil asked, so ${whe} gets my number.
        *set rel_wil +5
        *set telephone 3
        You shake off the urge. Why be contrary for the sake of contrariness?
        
        "Sure," you tell Wil, walking over to ${whim} to accept ${whis} phone and punch in your number. Soon enough, you hand the cell back.
        
        There's a certain deliberateness to how Wil approaches the operation. You realise that ${whe} was very careful to avoid touching you, or vice versa, @{touchingokay which you're not sure how to interpret.|an aversion you're no stranger to yourself. Still, best not to make assumptions.} 
        
    #I'm curious how Teddie will react.
        *set rel_teddie +3
        *set rel_kay +3
        *set telephone 1
        
        "You got your phone, Teddie?" you address him.
        
        Teddie gives you a flat stare. "Wil asked. Not me."
        
        "You're closer." Technically true, if half the width of a sofa can be considered a difference maker.
        
        "…Whatever." With a slowness you're certain is deliberate, he extracts his phone. He nods readiness, and you supply your number.
        
        Throughout the exchange, Wil has been glancing back and forth between you both like ${whe}'s spectating a tennis match. If ${whe}'s bothered by you turning ${whim} down, ${whe} doesn't show it, a small smirk on ${whis} face.
        
    #Actually, I think I'll give it to Kay.
        *set rel_kay +3
        *set rel_teddie +3
        *set telephone 2
        
        "Hey, Kay, you have your phone?" you call to her.
        
        Kay blinks in surprise, but then smiles. "Me? Well, okay!"
        
        "Ouch!" Wil chuckles. "Down in flames!" $!{whe} winks at you good-naturedly.
        
        "I didn't want to reach across everyone," you tell ${whim} as you approach the sofa. Not much of excuse, and there's a knowing smirk on Wil's face, though you're not sure what ${whe} thinks ${whe} knows. Kay hands you her phone—which has the thickest case you've ever seen—and lets you punch in your number.  "Thanks, Kay."
        
        "No problem, $!{aka}."

A couple of moments later, your phone beeps, @{telephone Teddie|Kay|Wil} has sent you a message.

[i]@{telephone .|hi! its kay!|yo}[/i]

@{telephone Well. That checks out. You glance up at him, but he's already looking away.|You glance up at her. She's smiling. You give her a nod.|You glance up at ${whim}, and ${whe} fires you a lazy salute.}

You add the number to your contacts. After a moment's deliberation, you input the name:

*if telephone = 1
    *choice
        #Teddie
            *set telname 1
        #T
            *set telname 2
        #spooky scary skeleton
            *set telname 3
        #sans
            *set telname 4
        #Skeletor
            *set telname 5
        #Mr. Bones' Wild Ride
            *set telname 6
    
*elseif telephone = 3
    *choice
        #$!{wname}
            *set telname 1
        #Wil
            *set telname 2
        #W
            *set telname 3
        #goth
            *set telname 4
        #Romero
            *set telname 5
        #Wil they or won't they
            *set telname 6
  
*else
    *choice
        #Kay
            *set telname 1
        #K
            *set telname 2
        #Special K
            *set telname 3
        #Baad Influence
            *set telname 4
        #Out on the Lamb
            *set telname 5
        #Showdown at the oKay Corral
            *set telname 6
    
Nodding with satisfaction, you stow your phone.

"Oh yeah!" Kay pipes up. "We should tell ${aka} our mask stuff!"

Teddie makes a dissenting noise in the back of his throat. "I think ${mc_he} can tell our 'stuff', Kay."

She's undeterred. "It's worth discussing! Plus, it's not like ${mc_he} can just psychically know our codenames."

"Unless ${mc_he}@{mc_singular 's|'re} a telepath," Teddie replies, deadpan.

"$!{mc_he}@{mc_singular  isn't!| aren't!}" Kay hesitates, then glances at you. "Right?"
*choice
    #"No."
        *set rel_kay +2
        "See!"
        
        Teddie shrugs his less bony shoulder, uninterested in a discussion.
        
    #"Actually, I am."
        *set rel_teddie +2
        Kay double takes. "Wait, really?"
        
        Is that a smirk on Teddie's face? Surely not. "No. Architect said. Scatterhead."
        
        *goto dionmusthave
    #"Wouldn't you like to know?"
        *set expressive %+ 5
        *set rel_wil +2
        You adopt your best ${mc_man} of mystery tone. Kay hesitates.
        
        "$!{mc_he}@{mc_singular  isn't| aren't}," says Wil, an amused look on ${whis} face. "Which you'd know if you listened to Dion earlier."
        
        *label dionmusthave
        "Oh… right." Kay's cheeks go pink.
        
        You wonder when Dion filled them in about you. Given the reception you got, he couldn't have said much beyond your powers.
        
"Anyway, Kay, we all know that you're just looking for an excuse to share that mask name you're so terribly proud of," Wil drawls.

"That isn't it," she protests, giving ${whim} a playful shove. "Don't listen to Wil," she tells you. "$!{whe} just thinks ${whe}'s funny."

"I'm hilarious."

"Sure, whatever. [i]Anyway[/i]," Kay refocuses on you yet again. "I'll go by Rampage."
*choice
    #"Oh, I get it."
        She winks. Those strange pupils turn an ordinary expression disconcerting.
        
    #"Cool." A name's a name.
        She deflates slightly. Maybe Wil was right.
        
    #"You were eager enough to be a villain to plan this out?"
        The question catches her by surprise and she pauses, looking away. "It's… well. I think it's something that everyone with powers thinks about sometimes."
        
        You nod, because it fits best with your cover.
        
"I'll be Ghoul," Wil adds.

Both look at Teddie. He holds out for several seconds, and then sighs. "Fracture."

"$!{mask}," you tell them, pre-empting their scrutiny.

"Neat!" Kay opens her mouth, then shuts it again. She takes a deep breath, and then casually not-casually asks. "What powers do you have? If you don't mind me asking."

[i]…reaction has manifested in a flexible membrane coating much of the shoulders and head. Preliminary testing indicates that subject's senses are unimpaired by this membrane. Furthermore, subject has produced two additional appendages from their shoulders. These tendrils possess excellent mobility and strength. With time, subject—[/i]

You shovel the analytical voice out of your head, swallowing down your nausea.
*choice
    #Provide as few details as possible. I don't want to think about this.
        *set hate +1
        *set expressive %- 5
        "I have tendrils and a protective membrane," your tone is emotionless and dull even to your own ear.
        
        The memories are sour in your mind. You don't need any reminders.
        
    #Explain my powers, trying to muster some enthusiasm.
        *set expressive %+ 5
        *set content +1
        "Well, firstly there's my tendrils; they come out of my shoulders and I can use them for attack, defence, and mobility. Then there's my membrane, which does a great job of protecting against hits."
        
        The memories are just memories. They can't hurt you. Better to focus on the positives, slender as they are.
        
    #Give a brief and factual rundown. It makes sense to tell them.
        *set trade +1
        "So mainly I can bring out this membrane to cover most of my head and shoulders. It absorbs punishment pretty well. I've also got a pair of tendrils, which I use flexibly depending on the circumstances."
        
        It's unpleasant to dwell on the memories. Best to get the necessary information delivered and hurry past the topic.
        
Even so, you could also tell them about your other abilities. Might gain you a little more trust.
*choice
    #I'll explain my @{speciality nodes|mutations|carapace|} too.
        "Also, @{speciality I can make these—well, I call them nodes. They're a little difficult to describe, but basically they can move around by themselves and jump onto people if I need them to.|my powers can make large scale changes to my body, which helps out in a pinch. Unfortunately it's pretty unpredictable, so I don't do that unless I have to.|I can turn the membrane into a carapace for even more protection. It's a little on the heavy side, though.|DUMMY}"
        
        *if speciality = 3
            Wil turns to Teddie. "Hey, sounds a bit like you, T—"
            
            "No it's not," Teddie cuts ${whim} off sharply.
            
            Wil stops, smiles, and shrugs. "You'd know best."
            
        *elseif speciality = 2
            "That sounds rough," says Kay, suddenly very quiet. Teddie nudges her with his arm, and she smiles at him weakly.
            
            "It can be," you reply.
            
        *else
            "Interesting," says Wil. "I'd like to see that in action sometime."
            
            "You'll get a demonstration sooner or later," you reply.
            
    #I keep the rest to myself.
        You've said enough. They'll learn the rest when it's relevant.
        
*if wimpression != 2
    *set wimpression 1
The talk peters out, and with the conversation coming to its natural conclusion, you figure that you've given Dion and Mallory enough time.

*if expressive > 60
    You rise. "Okay, I'm going to scoot."
    
*elseif expressive < 40
    You rise. "Heading out."
    
*else
    You rise. "Okay, I'm heading out."
    
@{telephone To your surprise, Teddie also stands. "I'll see you down there." Despite the offer, he's avoiding eye contact.|Kay also stands. "I can walk you down if you'd like, $!{aka}," she offers.|Wil also stands. "Let me walk you down, $!{aka}," ${whe} says. "Need to stretch my legs anyhow."}
*fake_choice
    #"I'm not going to get lost," I joke.
        *set expressive %+ 5
        *if telephone = 2
           *set rel_kay +3
           
        @{telephone Teddie doesn't respond. Tough crowd.|"I don't know about that. Our stairwell is pretty treacherous," Kay replies playfully, giving you a quick little smile.|"You never know," Wil replies. "Might run into those stair bandits."}
    #"If you want."
        @{telephone Teddie doesn't seem to deem a response necessary.|"I do want," Kay replies.|"You know it," Wil replies.}
    #I shrug. It doesn't really make a difference to me.
        *set expressive %- 5
        *if telephone = 1
            *set rel_teddie +3
        @{telephone Teddie nods, seemingly more to himself than to you.|That's as good as an acceptance in Kay's book.|Wil seems to take that as a yes.}
        
@{telephone He|Kay|Wil} moves across the room to join you.

*if telephone = 3
    "You two behave while I'm gone!" ${whe} calls. "No house parties, okay?"
    
    Teddie leans back in his seat and projects perhaps the most powerful aura of disinterest you've ever seen.
    
    "Calling all my friends as we speak," Kay replies.
    
*elseif telephone = 2
    "See you guys in a few," she calls.
    
    "Bye," Teddie answers, directing the word exclusively to Kay.
    
    For ${whis} part, Wil at least gives you a wave.
    
*else
    "Come on," he says, walking right past.
    
    Kay and Wil both see you off with a wave.
    
*page_break Follow @{telephone Teddie|Kay|Wil}

*if telephone = 1
    *goto teddiescene

*elseif telephone = 2
    *goto kayscene

*else
    *goto wilscene

*label teddiescene
With the quiet you're growing to expect, Teddie leads you out of the apartment and down the stairs. His tread is heavy, a little laboured. You have to slow down so as not to overtake him.

Reaching the bottom, Teddie stops and turns to you. He doesn't speak, just looks.

*goto midscene

*label midscene
*if expressive = 60
    "Something on my face?"
    
*elseif expressive < 40
    You raise an eyebrow.
    
*else
    "Yeah?" you prompt, after a moment.
   
*if telephone = 1
    *goto teddiemid

*elseif telephone =2
    *goto kaymid

*else
    *goto wilmid

*label teddiemid
*temp teddienod false
"Better be worth it," he mutters.
*choice
    #"Me?"
        "All of it. Everything."
        
    #"The team?"
        *set teddienod true
        Teddie nods slowly.
        
    #Let the comment pass.
        After a moment, he breaks eye contact on his own.
        
Silence. Teddie grips at one of the wicked hooks on his arm, worrying it back and forth. Eventually he stops, cradling his arm at the elbow. "Don't make me regret this."

*if observation > 35
    Though his expression is guarded, there's an instant where you see something vulnerable in his eyes.
*else
    His expression is guarded. He's a tough read.
    
*choice
    #Assure him. "You won't."
        "Easy to say," Teddie replies.
        
        "Then I'll prove it."
        
        Despite your assertion, he appears unmoved.
        
    #Hold my ground. "Likewise."
        *set rel_teddie +2
        @{teddienod Another|A} slow nod. "Yeah. Okay. Goes both ways."
        
    #Be blunt. "Then don't fuck it up."
        *set rel_teddie +2
        A thin smile comes and goes on his mouth. "Fair."
        
    #I'm sick of this. "Get off my damn back."
        *set antagonise true
        *set rel_teddie -3
        *set brushoff true
        *if observation > 35
            The portcullis of emotions slams shut, and Teddie's back to scowling.
            
        *else
            If you thought Teddie's face was guarded before, now it's barricaded, fortified, and preparing for a siege.
            
        "Fine," he growls.

Patience for conversation expended, Teddie pushes through the door and leads you back to the building's entrance. He stands to the side to let you past, arms folded and eyes watchful.

@{brushoff He gives the barest of nods|"See you," he says} as you step outside and onto the sidewalk.

*goto exitexit

*label teddieend
*choice
    #He's interesting, I'd like to get to know him.
        You can't deny that for all his prickles, Teddie has caught your attention. You wouldn't have made a point of giving him your number otherwise. Hopefully your hunch that there's more to him than the abrasive exterior isn't unfounded, although you'll probably need to @{antagonise quit butting heads with him|keep up with the tact} to get that far. @{antagonise Might be a challenge.|Shouldn't be too difficult. Probably.}
        
        Is it too much to hope you might make a friend of him someday? You feel a pang of longing, and hurriedly steer away from thoughts of when last you had a true friendship. You're trying to stay afloat, not sink without a trace.
        *goto endscene
    #It's not especially hard to picture him as a villain.
        While you're thinking more about Teddie's demeanour than his appearance, all those growths of bone hardly scream 'good guy'. A hero team's PR department would have nightmares trying to market him. Regardless, you can easily imagine him wreaking havoc and menacing bystanders with the best of them. Or should that be the worst of them?
        
        And even if Teddie was the very picture of a clean cut hero with the attitude to match, you can't forget that unlike you, he's willingly signing up for Dion's outfit. By contrast, even if you wanted to fight the good fight, the Coven's long leash is a fetter you can't slip.
        
        Teddie's making a choice, not following an order. You need to be on your guard, with him and with all the others too.
        *goto endscene
    #He seems naturally suspicious. I'll have to watch out.
        *set instinctive %- 5
        If anyone's going to seize on gaps in your cover, it's Teddie, and you can't imagine that he'll be easily placated by excuses. In that regard he represents a very real threat to your security; you can't afford for doubts to snowball.
        
        You're constantly calculating the ways you could be discovered, the right balance of truth and deception. How does that feel?
        *choice
            #It sucks. I wish I had another choice.
                *set seethe +1
                Nobody said survival was fun. Unfortunately, if you want to stay alive, you have to dance this dance.
                
                And dream of another.
            #Hopeless.
                *set break +1
                None of these choices are your own. You're dancing on the Coven's strings, and no reward awaits for success.
            #My feelings aren't relevant.
                *set loyal +1
                Orders are orders. There's no point bringing emotions into this.
                
        *goto endscene
    *selectable_if ((aro != 4) and (not (antagonise))) #...I'm attracted to him, aren't I? @{ftone [Flirt, passive]|}
        *set interest_teddie true
        *set flirt_teddie +1
        
        *if (brokenheart < 5)
            *label teddiebh
            However, just as soon as the realisation hits it's swept away by a wave of guilt, leaving a raw ache to settle in your chest. Are you really looking at @{telephone Teddie|DUMMY|Wil} like that? Like $!{prev_li} doesn't even matter?
            
            *if (telephone = 1)
                *if (brokenheart = 1)
                    There's just a little of Beth's bite in Teddie. A ghost of the blunt wit. Enough to twist the knife.
                
                *elseif (brokenheart =4)
                    Teddie doesn't have much in common with Grant, but maybe they're just different shades of bad boy. Having the thought is enough to twist the knife a little further.
       
            *elseif (telephone = 3)
                *goto wilbh
                
            *goto brokenheart
            
        *else
            Dammit.
        
            Of course it'd be the surly one.
            
            Okay. Fine. Whatever. You're a grown up. You can admit when you think someone's hot. At least you know you're not shallow, since the extra bones clearly aren't putting you off that much.
            
            Truly you are the font of good ideas today.
            *goto endscene
        
        
    *selectable_if ((aro != 4) and (antagonise)) #...He's hot. Why the fuck is he hot? @{ftone [Flirt, passive]|}
        *set interest_teddie true
        *set flirt_teddie +1
        *set t_teddie true
        You actually feel a little offended.
        
        *if (brokenheart < 5)
            *goto teddiebh
        
        *else
            Clearly the perfect subject for attraction is a surly guy whom you've butted heads with immediately. Bang up job, brain. Can't wait for the upcoming fiasco that this is sure to be.
            
            But fine. FINE. You're an adult. You can acknowledge attraction when it's there.
            *goto endscene

*label kayscene
You haven't known Kay long enough to determine whether the subdued pall that falls on her as she leads you out of the apartment is unusual. She trots her way down the stairs, sparing a quick glance for you at each landing.

She's waiting for you at the bottom, watching carefully.

*goto midscene

*label kaymid
"Sorry, just thinking."
*choice
    #"What about?"
        "Stuff," is her unhelpful answer.
        
    #"Oh, okay."
        "Mm."
        
After a few seconds of increasingly awkward silence, Kay lets out a big huff. "Sorry!" she says again. "I'm just—I'm not great with new people, and you seem cool, and I guess I keep getting caught up thinking you'll think I'm some kind of loser."
*choice
    #"Cool? Me? I can assure you that you're mistaken."
        *set rel_kay +3
        Kay grins at you. "Ever considered that you give a really cool first impression? Maybe you've been cool the whole time but you keep undermining yourself."
        
        *if expressive > 44
            "Nah," you tell her. "I give the game away as soon as I start talking."
            
            "You're managing to keep it up so far."
            
        *else
            You shrug. "People just mistake quiet for cool."
            
            "You can be both!" Kay asserts.
            
        "Maybe, maybe."
        
    #"You're right." I leave a beat. "I'm very cool."
        *set rel_kay +2
        Your bait and switch scores you a giggle that she immediately and self-consciously stifles with the back of her hand. 
        
    #"I don't think you're a loser." Try to calm her.
        *set rel_kay +3
        Kay closes her eyes, but she's also smiling. "See, I spent the whole walk down telling myself that, but the bad brain gets me every time." Her eyes reopen. "Thanks, $!{aka}. Hearing it from you helps."
        
        "No problem."
        
    #"You're overthinking it." We literally just met.
        Kay sighs, pressing a palm to her head. "I know, I know. It's just bad brain."
        
        You say nothing, allowing her a moment to pull herself together. To her credit, she rallies swiftly.
        
    #"We aren't here to be friends." Better to keep things professional.
        *set brushoff true
        *set rel_kay -2
        All the wind drops from Kay's sails. "I suppose," she murmurs. "Only I figured—" she breaks off and shakes her head. "No, you're right. Nevermind."
        
        It's a little harsh, but maintaining distance is the pragmatic approach.
               
The two of you regard one another for a moment, and then both try to fill the sudden silence at once.

"Anyway—"
"I should—"

You both break off. It's Kay that resumes.

"Anyway, I've kept you long enough," she says. "It's been nice meeting you, $!{aka}."
*choice
    #"Later."
        That gets you a nod and a quick smile.
         
    #"Same to you."
        She smiles@{brushoff , although it's a little uncertain. Probably because you brushed her off.|.}
        
    #Nod politely.
        *set expressive %- 5
        She returns the nod with a quick smile.
        
Following Kay to the building's entrance, she holds the door open for you. "Take care!" she calls as you step onto the sidewalk.

*label exitexit
You raise a hand in acknowledgement and set off into Alderbrook at a steady clip. Back to your own company. A chance to decompress and assess. Consider all the new faces.

Another group of five. Well. Six with you. Your pace slows, the realisation plunging into your stomach like an anchor. You grasp for another thought, a distraction to serve as a life buoy.

Naturally, it's @{telephone Teddie|Kay|Wil} who comes to mind first.
*if telephone = 1
    *goto teddieend

*elseif telephone = 2
    *goto kayend

*else
    *goto wilend

*label kayend
*choice
    #I'm looking forward to getting to know her.
        Undoubtedly you'll have opportunities to spend time with Kay and the others in the coming weeks. (months?) Kay in particular seems to be the kind of person that you could grow to like, and focusing on that optimism is enough to bring you back up from the depths—if just barely.
        
        She's… nice. That's a start, right?
        
        *label steer
        You desperately steer away from thoughts of when last you made a friend, lest you resume sinking without a trace. Focus on the here and now. The hope. The pale and flickering light in the darkness.
        *goto endscene
    #I can't forget that she's willing to be a villain.
        Maybe it's hypocritical of you to judge another's morals@{brutality —especially with how you took care of business yesterday—| }when you're also on the wrong side of the law, but your hands are tied. Even if you wanted to fight the good fight, the Coven's long leash is a fetter you can't slip.
        
        No matter how personable Kay is, she's still taking the low road. A choice to make, not an order to follow. You need to be on your guard, with her and with all the others too.
        *goto endscene
    #She seems trusting. That'll be useful.
        *set instinctive %- 5
        It's a dangerous game you're playing. One wrong move, one word out of turn, and your house of cards could come crashing down in an instant.
        
        Provided your read on Kay is correct, she'll be an angle that you have to worry about a little less. Perhaps even an unwitting source, if you're careful and subtle.
        
        Plotting to take advantage of someone's good nature… how does that feel?
        *choice
            #Like I'm trapped. Better her than me, but...
                *label trapped
                *set seethe +1
                …but you know it's wrong.
                
                You just don't have a choice. If you don't think this way, then you'll fail. And you can't let that happen. 
                *goto endscene
            #Sickening. Is this who I am?
                *label sick
                *set break +1
                Once upon a time you were better than this, you're sure of it.
                
                You just… have trouble remembering exactly when.
                *goto endscene
            #I'm numb to it. These are my orders.
                *label numb
                *set loyal +1
                Your feelings are irrelevant. You have a command to follow, and you're following.
                
                If that means getting your conscience a little dirty, then so be it.
                *goto endscene
    *if (not (cis)) #My queer radar is going off something fierce.
        You feel the same intuitive kinship with Kay that you've always associated with fellow gender anarchists. You aren't sure where she sits on that rainbow and you aren't going to pry unless she raises the topic herself, but between you, @{wilqueer Wil, |}Kay, and whatever Mallory has going on, it seems as if your new group will be plenty queer.
        
        The phrase 'be gay, do crimes' has never been more apt.
        *goto endscene
    *selectable_if (aro !=4) #What better distraction than a cute girl? Uh, wait... @{ftone [Flirt, passive]|}
        *set interest_kay true
        *set flirt_kay +1
        You mentally double take.
        
        *if (brokenheart < 5)
            *label backspace
            Then you mentally backspace, a raw ache settling into your chest. Look at your head getting turned as soon as you run into someone attractive. Like $!{prev_li} doesn't mean a thing.
            
            Fuck. Dammit. Fuck.
            
            *if telephone = 2
                *if ((brokenheart = 2) or (brokenheart = 3))
                    It's much, much too easy to see flashes of @{brokenheart DUMMY|Prii in Kay. The charm. The sense of humour.|Shauna in Kay. The earnestness. The playful undercurrent.|DUMMY|DUMMY} Not a one to one match but enough. Too much.
                
                *label brokenheart
            
                Tears prick your eyes. Turns out that what you thought was a life buoy is actually ballast.
                *goto endscene
            
            *elseif telephone = 3
                *label wilbh
                *if ((brokenheart = 2) or (brokenheart = 4))
                    It's much, much too easy to see flashes of @{brokenheart DUMMY|Prii in Wil. Charming. Friendly. Assertive.|DUMMY|Grant in Wil. Laid back, but with an edge. The dry humour.|DUMMY} Not a one to one match but enough. Too much.
                    
                    
                *goto brokenheart
        *else
            Uh…
        
            Okay you're an adult, you can admit that you find Kay attractive; her strange features pull together in a way that works surprisingly well, and she's got both earnest charm and a sense of humour. Doesn't mean it has to go any further than the admission. Going further than the admission would be a terrible, terrible idea. @{brushoff You were literally just telling yourself that pragmatic distance is the best way to conduct your business.|You can't afford to get in too deep.} @{aro |DUMMY|While you're comfortable enough with your absence of romantic interest to know you're not at any risk of catching feelings, the reverse would be an awkward complication.|DUMMY}
            
            At least you can consider yourself thoroughly distracted.
            *goto endscene  
                
*label wilscene
Wil is quiet as ${whe} leads you out of the apartment and down the stairs. $!{whe} steps lightly, footfalls making no noise as you descend together.

$!{whe} halts at the bottom, turning and then taking a backward step to lean against the wall.

*goto midscene

*label wilmid
*if wimpression = 2
    *if (antagonise)
        "Did you have to push Teddie's buttons?" $!{whe} fidgets around with ${whis} fingers.
        
        *choice
            #I'm unrepentant. "He got in my face. I got in his."
                *label inmyface
                *set brushoff true
                *set rel_wil -2
                Wil shakes ${whis} head, brow furrowed. "Think you're missing the point of why I asked. But fine. Fine."
                
                You feel a small sense of satisfaction at seeing ${whim} back down.
                *goto wilfin
            #I'll apologise. "Sorry. I don't like getting pushed around." 
                *set wimpression 3
                Wil grips ${whis} own knuckles for a moment, smiling ruefully. "Yeah, that makes sense. Having you and Teddie on the team is going to be interesting."
                
                *label wilpology
                "Sorry," you repeat, in lieu of anything better to say.
                
                $!{whe} shrugs. "Onwards and upwards, right?"
                *goto wilfin

    *else
        "Thanks for playing nice. I know you weren't thrilled about that whole talk."
        
        *choice
            #"You're right. I wasn't." $!{whe} better remember this.
                *label playnice
                *set wimpression 3
                *set instinctive %+ 5
                *set rel_wil +2
                Wil at least looks sheepish. "I can't promise that Teddie will be your best friend tomorrow or anything, but give him time. And for what it's worth, I'm sorry for grilling you."
                
                You nod. You'll reserve judgement on ${whis} sincerity.
                *goto wilfin
            #"Don't mention it." I want to let this go.
                *label letitgo
                *set wimpression 3
                *set instinctive %- 5
                *set rel_wil +5
                Wil smiles. "You're a gem, $!{aka}."
                
                You glance away, a little embarrassed by the compliment.
                *goto wilfin


*else
    *if (antagonise)
        "Did you have to push Teddie's buttons? I thought we had an understanding." Wil looks upset.
        
        *choice
            #"I didn't agree to take shit." I'm not backing down.
                *set wimpression 2
                *goto inmyface
            #I'll be diplomatic. "I'm sorry. I shouldn't have reacted."
                Wil sighs. "It's fine. Everyone could have handled that better."
                
                *goto wilpology
        
    *else
        "Thanks for playing nice. I know Teddie can be hard work."
        
        *choice
            #"Yeah, you got that right." That wasn't easy.
                *goto playnice
            #"Don't mention it." I'd like to keep up the good impression.
                *goto letitgo
        

*label wilfin
Having said ${whis} piece, Wil opens the door out of the stairwell and takes you to the building's entrance. Wil holds the exit for you. @{brushoff "Bye then."|"See you around, $!{aka}."}

*goto exitexit

*label wilend
*choice
    #I think we could be friends.
        @{brushoff You've disagreed with Wil, but you can work past that, you're sure.|Wil seems plenty friendly, despite only knowing ${whim} for a short while.} Undoubtedly you'll have the opportunity to spend plenty of time with Wil and the others over the coming weeks. (months?) Focusing on that optimism is enough to bring you back up from the depths—if just barely.
        
        It's a start, right?
        
        *goto steer
    #I shouldn't forget that ${whe}'s a willing villain. 
        @{brushoff Argument notwithstanding,|On the face of it,} Wil seems pretty genial. However, you can't overlook that the entire reason you met was ${whim} signing up to a life of crime. Sure, you're also on the wrong side of the law, but your hands are tied. Even if you wanted to fight the good fight, the Coven's long leash is a fetter you can't slip.
        
        Wil's making a choice, not following an order. You need to be on your guard, with ${whim} and with all the others too.
        
        *goto endscene
    #$!{whe} could be either a threat or an asset to the mission.
        *set instinctive %- 5
        Depends how you play things. You've seen two sides of Wil already. Blunder, and ${whe} seems sharp enough to punish you. On the other hand, if you can get ${whim} onside, ${whe} seems pretty loyal. You could possibly use ${whim} as a source of information.
        
        Plotting how best to exploit a new acquaintance… how does that feel?
        *choice
            #Like I'm trapped. Better ${whim} than me, but...
                *goto trapped
            #Sickening. Is this who I am?
                *goto sick
            #I'm numb to it. These are my orders.
                *goto numb
    *selectable_if (brushoff) #We're going to argue more if ${whe} doesn't chill.
        *set expressive %+ 5
        *set seethe +1
        Ideally you'd get along, but ideally Wil wouldn't be all on your back too. You've taken a lot of shit over the years and your tolerance has its limits. Especially when you actually have the option to stand up for yourself.
        
        So. Jury's out.
        *goto endscene
    *if ((aro !=4) and (not (brushoff))) #Not going to lie, ${whe}'s kind of hot. Uh. Wait. @{ftone [Flirt, passive]|}
        *set interest_wil true
        *set flirt_wil +1
        You mentally double take.
        
        *if (brokenheart < 5)
            *goto backspace
            
        …Uh. 
        
        Okay, you're an adult. You can admit that you find Wil attractive. The fashion. The style. The dry humour mixed with charm. Doesn't mean it has to go any further than the admission. Going further than the admission would be a terrible, terrible idea. @{aro |DUMMY|While you're comfortable enough with your absence of romantic interest to know you're not at any risk of catching feelings, the reverse would be an awkward complication.|DUMMY}
            
        At least you can consider yourself thoroughly distracted.
        *goto endscene
    *if ((aro != 4) and (brushoff)) #Why is it always the hot ones who are total pains in the ass? @{ftone [Flirt, passive]|}
        *set interest_wil true
        *set t_wil true
        *set flirt_wil +1
        …Oh goddammit ${whe} [i]is[/i] hot, isn't ${whe}?
        
        *if (brokenheart > 5)
            *goto teddiebh
        
        *else
            Clearly the perfect recipe for attraction is to instantly start clashing with someone, and then double down. That makes perfect sense and is in no way primed to explode.
            
            Tremendous job, brain. Truly.
            *goto endscene

*label endscene
*page_break
*achieve entrylevel

As you move further into the city, you begin considering how to spend the rest of your day. At this stage you've got it to yourself and while any activity that costs money is off limits thanks to your barely extant budget, you have plenty of options.
*choice
    #I might just keep walking. Get a better feel for the streets.
        Improving your knowledge of the city can't hurt—
    #There's a public library somewhere around here.
        Books and internet. A perfect combination—
    #Time to investigate the pasta mystery.
        You're still concerned about the random drop on your doorstep—
    *if (pasta) #Time to 'investigate' the mystery pasta. (Eat it. I'm going to eat it).
        You're hungry. You have pasta. The solution is simple—
    #I could use a rest. @{injured My injuries will thank me for it.|}
        Catching your breath is probably a good idea—
        
*finish There's no warning.